WormbotReporter.WIR_RegistrationQuakeNet

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Auths the client with Q.
******************************************************************************/


class WIR_RegistrationQuakeNet extends WIR_RegistrationHandler;


//=============================================================================
// Configured Variables
//=============================================================================

var bool bAuth;
var bool bChallengeAuth;
var bool bHideRealHost;
var string AuthNick;
var string AuthPassword;
var bool bDeaf;


//=============================================================================
// Variables
//=============================================================================

var bool bAuthed;
var bool bRealHostHidden;


//== Reset ====================================================================
/**
Resets the registration state. Should be subclasses.
*/
//=============================================================================

function Reset()
{
	bAuthed = False;
	bRealHostHidden = False;
}


//== Register =================================================================
/**
Starts the registration process. Should be subclasses.
*/
//=============================================================================

function Register()
{
	local string Network, Modes;

	if ( Outer.GetNetworkParameter("Network", Network) && Network ~= "QuakeNet") {
		Modes = "+iR";
		if (bHideRealHost) Modes $= "x";
		if (bDeaf)         Modes $= "d";
		Outer.SendCommand("MODE" @ UserNick @ Modes, True);
		if (bAuth ) {
			if ( bChallengeAuth )
				Outer.SendCommand("PRIVMSG Q@CServe.QuakeNet.org :CHALLENGE", True);
			else
				Outer.SendCommand("PRIVMSG Q@CServe.QuakeNet.org :AUTH" @ AuthNick @ AuthPassword, True);
		}
	}
	else {
		Super.Register();
	}
}


//== ReceivedString ============================================================
/**
Handles a string message received from the server.
*/
//=============================================================================

function ReceivedString(string Command, string Server, string Target, string Parameters)
{
	if ( !bAuthed && Command == "NOTICE" && Server ~= ":Q!TheQBot@CServe.quakenet.org" && Target ~= UserNick ) {
		if ( Left(Parameters, 11) == ":CHALLENGE " ) {
			Outer.SendCommand("PRIVMSG Q@CServe.QuakeNet.org :CHALLENGEAUTH" @ AuthNick
				@ class'WIR_Util'.static.HMACMD5String(class'WIR_Util'.static.MD5String(class'WIR_Util'.static.ToIRCLower(AuthNick) $ ":" $ class'WIR_Util'.static.MD5String(Left(AuthPassword, 10))), Mid(Parameters, 11, 32)) @ "HMAC-MD5", True);
		}
		else if ( Parameters ~= ":AUTH'd successfully." || Parameters ~= ":CHALLENGEAUTH'd successfully." ) {
			bAuthed = True;
			if ( !bHideRealHost ) {
				Outer.Registered();
				bRegistered = True;
			}
		}
		else {
			log("Response from Q:"@Parameters, Name);
		}
	}
}


//== ReceivedNumeric ============================================================
/**
Handles a numeric message received from the server.
*/
//=============================================================================

function ReceivedNumeric(int Command, string Server, string Target, string Parameters)
{
	if ( Command == 396 ) {
		bRealHostHidden = True;
		Outer.Registered();
		bRegistered = True;
	}
}