MultiDodging2k4v4.MultiDodgingRules

/**
MultiDodging2k4v4.MultiDodgingRules

Creation date: 2014-01-04 19:43
Last change: $Id$
Copyright (c) 2014, Wormbo
*/

class MultiDodgingRules extends GameRules;


//=============================================================================
// Configuration
//=============================================================================

var int  MaxDodgesPerJump;
var bool bAlwaysAllowDodgeDoubleJump;
var bool bEnableBoostDodge;
var bool bFastDodging;


var transient Controller LastPlayer;
var transient float LastTimeSeconds;


function PreBeginPlay()
{
	MaxDodgesPerJump = class'MutMultiDodging'.default.MaxDodgesPerJump;
	bAlwaysAllowDodgeDoubleJump = class'MutMultiDodging'.default.bAlwaysAllowDodgeDoubleJump;
	bEnableBoostDodge = class'MutMultiDodging'.default.bEnableBoostDodge;
	bFastDodging = class'MutMultiDodging'.default.bFastDodging;
	
	AddToPackageMap();
	Level.Game.AddGameModifier(Self);
	Super.PreBeginPlay();
}

function NavigationPoint FindPlayerStart(Controller Player, optional byte InTeam, optional string IncomingName)
{
	local DodgeHandler DH;
	
	if (Player != None && (Player != LastPlayer || Level.TimeSeconds != LastTimeSeconds))
	{
		LastPlayer = Player;
		LastTimeSeconds = Level.TimeSeconds;
		
		if (bEnableBoostDodge)
			Enable('Tick');
		
		foreach Player.ChildActors(class'DodgeHandler', DH)
		{
			break;
		}
		
		if (DH == None)
		{
			DH = Spawn(class'DodgeHandler', Player);
			DH.MaxDodgesPerJump = MaxDodgesPerJump;
			DH.bAlwaysAllowDodgeDoubleJump = bAlwaysAllowDodgeDoubleJump;
			DH.bFastDodging = bFastDodging;
		}
	}
	
	return Super.FindPlayerStart(Player, InTeam, IncomingName);
}

function Tick(float DeltaTime)
{
	local xPawn P;
	
	if (bEnableBoostDodge)
	{
		foreach DynamicActors(class'xPawn', P)
		{
			P.bCanBoostDodge = True;
		}
	}
	Disable('Tick');
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
     MaxDodgesPerJump=-1
     bAlwaysAllowDodgeDoubleJump=True
     bFastDodging=True
}