UTANBanManager104.UTANBanDatabase

/******************************************************************************
UTAN Ban Manager v1.04                                                   <br />
Coded by Wormbo, Copyright © 2003-2006 UTAN, 2009-2011 Wormbo       <br />
																		 <br />
Stores the UTAN bans affecting this server.
******************************************************************************/


class UTANBanDatabase extends Object dependson(MutUTAN);


//=============================================================================
// Structs
//=============================================================================

/** Compressed ban data. */
/*
Why is this a struct of two rotators?
Well, rotators are serialized extremely efficiently and only require exactly
3 * 4 = 12 bytes, plus the overhead for two struct members.
Ban data consists of a ban ID (relatively small positive int), an IP in CIDR
notation (can also be expressed as 32 bit for the IP part and 5 bits for the
CIDR prefix), a GUID (128 bit = 4 ints) and several boolean flags. (1 bit each)

The ban ID is stored in A.Pitch. Because the ID is always positive and usually
quite small, the most significant bits of A.Pitch are used for the CIDR prefix
and the various flags. The IP is stored in A.Yaw.
A.Roll, B.Pitch, B.Yaw and B.Roll provide the space for the 4 ints of the GUID.

See the GetEntry() and AddEntry() functions for storage details of the ban ID,
flags and CIDR prefix.
*/
struct TBanData {
	var rotator A, B;
};

/**
A ban reason. These are stores separately, if present.
*/
struct TBanReason {
	var config int ID;
	var config string Reason;
};


//=============================================================================
// Variables
//=============================================================================

/**
The actual ban list data. Bans can consist of more than one entry here,
identified by the same ban ID value.
Additionally, ban excludes also reside in this list, indicated by the exclude
flag in bit 23 of A.Pitch.
*/
var array<TBanData> BanList;
/**
Last remote update time as seconds since epoch.
Sent when communicating with the configured masterserver.
*/
var config int LastUpdate;
/**
Ban reasons.
*/
var config array<TBanReason> BanReasons;

var transient array<int> SortedReasons;


function Init()
{
	local int i, Low, Middle, High;

	if (BanReasons.Length > 0) {
		SortedReasons[i++] = 0;
		if (BanReasons.Length > 1) {
			do {
				Low = 0;
				High = SortedReasons.Length;
				do {
					Middle = (High + Low) / 2;
					if (BanReasons[SortedReasons[Middle]].ID < BanReasons[i].ID)
						Low = Middle + 1;
					else
						High = Middle;
				} until (Low >= High);
				SortedReasons.Insert(Low, 1);
				SortedReasons[Low] = i;
			} until (++i == BanReasons.Length);
		}
	}
}


function int GetNumEntries()
{
	return BanList.Length;
}

function ClearEntries()
{
	BanList.Length = 0;
	BanReasons.Length = 0;
	SortedReasons.Length = 0;
}

function MutUTAN.TListEntry GetEntry(int Index)
{
	local MutUTAN.TListEntry Result;

	Result.ID          = BanList[Index].A.Pitch & 0x007FFFFF;
	Result.bIsExclude  = bool(BanList[Index].A.Pitch & 0x00800000);
	Result.bIsRemote   = bool(BanList[Index].A.Pitch & 0x80000000);
	Result.bIsCheater  = bool(BanList[Index].A.Pitch & 0x40000000);
	Result.bIsDisabled = bool(BanList[Index].A.Pitch & 0x20000000);
	Result.IP.Prefix   = BanList[Index].A.Pitch >> 24 & 0x1F;
	Result.IP.IP       = BanList[Index].A.Yaw & -1 << -Result.IP.Prefix;
	Result.GUID.A      = BanList[Index].A.Roll;
	Result.GUID.B      = BanList[Index].B.Pitch;
	Result.GUID.C      = BanList[Index].B.Yaw;
	Result.GUID.D      = BanList[Index].B.Roll;

	return Result;
}

function int AddEntry(MutUTAN.TListEntry ListEntry)
{
	local int i;

	i = BanList.Length;
	BanList.Length = i + 1;
	BanList[i].A.Pitch = ListEntry.ID & 0x007FFFFF | int(ListEntry.bIsExclude) << 23 | ListEntry.IP.Prefix << 24 | int(ListEntry.bIsDisabled) << 29 | int(ListEntry.bIsCheater) << 30 | int(ListEntry.bIsRemote) << 31;
	BanList[i].A.Yaw   = ListEntry.IP.IP;
	BanList[i].A.Roll  = ListEntry.GUID.A;
	BanList[i].B.Pitch = ListEntry.GUID.B;
	BanList[i].B.Yaw   = ListEntry.GUID.C;
	BanList[i].B.Roll  = ListEntry.GUID.D;
	return i;
}

function bool SaveDatabase(LevelInfo Level, string BanDatabaseName)
{
	return Level.Game.SavePackage(BanDatabaseName);
}


function string GetReason(int ID)
{
	local int Low, Middle, High;

	High = SortedReasons.Length;
	while (Low < High) {
		Middle = (High + Low) / 2;
		if (BanReasons[SortedReasons[Middle]].ID < ID)
			Low = Middle + 1;
		else
			High = Middle;
	}

	if (Low < SortedReasons.Length && BanReasons[SortedReasons[Low]].ID == ID)
		return BanReasons[SortedReasons[Low]].Reason;

	return "";
}

function SetReason(int ID, optional string Reason)
{
	local int Low, Middle, High;
	local int i;

	High = SortedReasons.Length;
	while (Low < High) {
		Middle = (High + Low) / 2;
		if (BanReasons[SortedReasons[Middle]].ID < ID)
			Low = Middle + 1;
		else
			High = Middle;
	}

	if (Reason == "") {
		// delete current reason
		if (Low < SortedReasons.Length && BanReasons[SortedReasons[Low]].ID == ID) {
			for (i = 0; i < SortedReasons.Length; i++) {
				if (SortedReasons[i] > SortedReasons[Low])
					SortedReasons[i]--;
			}
			BanReasons.Remove(SortedReasons[Low], 1);
			SortedReasons.Remove(Low, 1);
		}
	}
	else if (Low < SortedReasons.Length && BanReasons[SortedReasons[Low]].ID == ID) {
		// update reason
		BanReasons[SortedReasons[Low]].Reason = Reason;
	}
	else {
		// add new reason
		i = BanReasons.Length;
		BanReasons.Length = i + 1;
		BanReasons[i].ID = ID;
		BanReasons[i].Reason = Reason;
		SortedReasons.Insert(Low, 1);
		SortedReasons[Low] = i;
	}
}

//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
}