WormbotHandlerOLTeamGames.WIR_GameHandler_OLCTF

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Handler for CTF4.
******************************************************************************/


class WIR_GameHandler_OLCTF extends WIR_GameHandler_CTF;


//== CriticalPlayer ===========================================================
/**
Called when the match starts.
*/
//============================================================================= 

function bool CriticalPlayer(Controller Player)
{
  return Super.CriticalPlayer(Player) || OLTeamGame(Level.Game) != None
      && OLTeamGame(Level.Game).CriticalPlayer(Player);
}


//== HandleKill ===============================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleKill(out Controller Killer, out Controller Killed, out class<DamageType> DamageType, out string MsgSuffix)
{
  local array<string> Flags;
  local int i;
  
  if ( Killed != None && OLTeamsPlayerReplicationInfo(Killed.PlayerReplicationInfo) != None ) {
    for (i = 0; i < OLTeamsPlayerReplicationInfo(Killed.PlayerReplicationInfo).HasFlags.Length; ++i)
      if ( CTFFlag(OLTeamsPlayerReplicationInfo(Killed.PlayerReplicationInfo).HasFlags[i]) != None ) {
        LastDropped[LastDropped.Length] = CTFFlag(OLTeamsPlayerReplicationInfo(Killed.PlayerReplicationInfo).HasFlags[i]);
        Flags[Flags.Length] = GetObjectName(CTFFlag(OLTeamsPlayerReplicationInfo(Killed.PlayerReplicationInfo).HasFlags[i]), True);
      }
    if ( Flags.Length > 0 )
      MsgSuffix = Repl(StringFlagDropped, "%o", class'WIR_Util'.static.ConcatWithSeparator(Flags), True);
    return Super(WIR_GameHandler).HandleKill(Killer, Killed, DamageType, MsgSuffix);
  }
  return Super.HandleKill(Killer, Killed, DamageType, MsgSuffix);
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
  HandlerGroup = "Wormbot (CTF4)"
}