WVArtilleryTurretSupport.ONSSquadAIWithArtilleryTurretSupport

/**
Extended Onslaught Squad AI that takes artillery turrets into account.

Creation date: 2013-12-15 10:55
Copyright (c) 2013, Wormbo
*/

class ONSSquadAIWithArtilleryTurretSupport extends ONSSquadAI;


/** Reimplements the ONSVehicle artillery checks for artillery turrets as well. */
function bool CheckVehicle(Bot B)
{
	local ONSPowerCore Core;
	local GameObjective O;
	local int i;
	local Vehicle V;

	if ((ArtilleryWeaponPawn(B.Pawn) != None && ArtilleryWeaponPawn(B.Pawn).IsArtillery() || StationaryArtilleryWeaponPawn(B.Pawn) != None && StationaryArtilleryWeaponPawn(B.Pawn).IsArtillery()) && (B.Skill + B.Tactics >= 3 || ONSWeaponPawn(B.Pawn).bKeyVehicle))
	{
		if (ArtilleryWeaponPawn(B.Pawn) != None && ArtilleryWeaponPawn(B.Pawn).IsDeployed() || StationaryArtilleryWeaponPawn(B.Pawn) != None && StationaryArtilleryWeaponPawn(B.Pawn).IsDeployed())
		{
			// if possible, just target and fire at nodes or important enemies
			if (SquadObjective != None && SquadObjective.DefenderTeamIndex != Team.TeamIndex && ONSPowerCore(SquadObjective) != None && ONSPowerCore(SquadObjective).LegitimateTargetOf(B) && B.Pawn.CanAttack(SquadObjective))
			{
				B.DoRangedAttackOn(SquadObjective);
				B.GoalString = "Artillery Attack Objective";
				return true;
			}
			if (B.Enemy != None && B.Pawn.CanAttack(B.Enemy))
			{
				B.DoRangedAttackOn(B.Enemy);
				B.GoalString = "Artillery Attack Enemy";
				return true;
			}
			// check squad enemies
			for (i = 0; i < 8; i++)
			{
				if (Enemies[i] != None && Enemies[i] != B.Enemy && B.Pawn.CanAttack(Enemies[i])) 
				{
					B.DoRangedAttackOn(Enemies[i]);
					B.GoalString = "Artillery Attack Squad Enemy";
					return true;
				}
			}
			// check other nodes
			for (O = Team.AI.Objectives; O != None; O = O.NextObjective)
			{
				Core = ONSPowerCore(O);
				if (Core != None && Core.PoweredBy(Team.TeamIndex) && Core.DefenderTeamIndex != Team.TeamIndex && Core.LegitimateTargetOf(B) && B.Pawn.CanAttack(Core))
				{
					B.DoRangedAttackOn(Core);
					B.GoalString = "Artillery Attack Other Node";
					return true;
				}
			}

			// check important enemies
			for (V = Level.Game.VehicleList; V != None; V = V.NextVehicle)
			{
				if (V.Controller != None && !V.bCanFly && (V.ImportantVehicle() || V.IsArtillery()) && !V.Controller.SameTeamAs(B) && B.Pawn.CanAttack(V))
				{
					B.DoRangedAttackOn(V);
					B.GoalString = "Artillery Attack important vehicle";
					return true;
				}
			}
		}
		else if (!B.Pawn.IsFiring() && (B.Enemy != None) && B.Pawn.CanAttack(B.Enemy))
		{
			B.Focus = B.Enemy;
			B.FireWeaponAt(B.Enemy);
		}
	}

	return Super.CheckVehicle(B);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
}