ChristmasDecorationV2a.SantaHatAttachment

/******************************************************************************
SantaHatAttachment

Creation date: 2010-12-12 16:37
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class SantaHatAttachment extends StaticMeshActor notplaceable;


//=============================================================================
// Imports
//=============================================================================

#exec obj load file=SantaHat.usx package=ChristmasDecorationV2
#exec texture import file=Textures\SantaHatTexBlue.dds
#exec texture import file=Textures\SantaHatTexGreen.dds
#exec texture import file=Textures\SantaHatTexGold.dds


//=============================================================================
// Variables
//=============================================================================

var array<Material> TeamSkins;


simulated function PostNetBeginPlay()
{
	Super.PostNetBeginPlay();
	
    if (Level.Game != None)
		SetGRI(Level.Game.GameReplicationInfo);
	else if (Level.GRI != None)
		SetGRI(Level.GRI);
}


simulated function SetGRI(GameReplicationInfo GRI)
{
	local NavigationPoint NP;
	local GameObjective GO, BestGO;
	local float Dist, BestDist;
	local int TeamIndex;
	
	if (Owner != None && InStr(Locs(Owner.StaticMesh), "dead") != -1 && Owner.Skins.Length > 0)
	{
		TeamIndex = int(Right(Owner.Skins[0], 1));
		if (Right(Owner.Skins[0], 2) == ("_" $ TeamIndex))
		{
			Skins[0] = TeamSkins[TeamIndex];
			RepSkin = TeamSkins[TeamIndex];
			return;
		}
	}
	
	if (!GRI.bTeamGame || GRI.IsA('ASGameReplicationInfo'))
		return;
	
	for (NP = Level.NavigationPointList; NP != None; NP = NP.NextNavigationPoint)
	{
		GO = GameObjective(NP);
		if (GO != None && GO.DefenderTeamIndex < TeamSkins.Length && !GO.bTeamControlled)
		{
			Dist = VSize(Location - GO.Location);
			if (BestGO == None || Dist < BestDist)
			{
				BestGO = GO;
				Bestdist = Dist;
			}
		}
	}
	
	if (BestGO != None && BestGO.DefenderTeamIndex < TeamSkins.Length)
	{
		Skins[0] = TeamSkins[BestGO.DefenderTeamIndex];
		RepSkin = TeamSkins[BestGO.DefenderTeamIndex];
	}
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	DrawType    = DT_StaticMesh
	StaticMesh  = StaticMesh'SantaHatSM'
	RemoteRole  = ROLE_None
	bHardAttach = True
	MaxLights   = 8
	bStasis     = True
	bStatic     = False
	bNoDelete   = False
	bOnlyDrawIfAttached = True
	
	TeamSkins(0) = Texture'SantaHatTex'
	TeamSkins(1) = Texture'SantaHatTexBlue'
	TeamSkins(2) = Texture'SantaHatTexGreen'
	TeamSkins(3) = Texture'SantaHatTexGold'
}