OnslaughtSpecialsLiteV2.ACTION_DamagePowerNode

/******************************************************************************
Damages a power node or core directly, even if it is protected or belongs to
the instigator's team.

Creation date: 2010-08-09 13:32
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class ACTION_DamagePowerNode extends ScriptedAction;


var() name NodeTag;
var() int DamageAmount;
var() bool bAttackNotification;

var ONSPowerCore Node;


function bool InitActionFor(ScriptedController C)
{
	local Pawn Instigator;
	local PlayerReplicationInfo InstigatorPRI;

	if (Node == None && NodeTag != '') {
		foreach C.AllActors(class'ONSPowerCore', Node, NodeTag) {
			break;
		}
		if (Node == None) {
			log(C.SequenceScript@C.ActionNum@Name@"- No power node/core for tag '"$NodeTag$"'");
			NodeTag = '';
		}
	}

	if (Node == None || Node.Health < 0 || DamageAmount <= 0 || Node.CoreStage != 0 && Node.CoreStage != 2)
		return false;

	Instigator = C.GetInstigator();
	if (Instigator != None)
		InstigatorPRI = Instigator.PlayerReplicationInfo;

	if (InstigatorPRI != None && Controller(InstigatorPRI.Owner) != None) {
		Node.LastDamagedBy = InstigatorPRI;
		Node.LastAttacker = Instigator;
		Node.AddScorer(Controller(InstigatorPRI.Owner), FMin(Node.Health, DamageAmount) / Node.DamageCapacity);
	}
	Node.NetUpdateTime = C.Level.TimeSeconds - 1;
	Node.AccumulatedDamage += DamageAmount;
	if (Node.DamageEventThreshold > 0 && Node.AccumulatedDamage >= Node.DamageEventThreshold) {
		Node.TriggerEvent(Node.TakeDamageEvent, Node, Instigator);
		Node.AccumulatedDamage = 0;
	}

	Node.Health -= DamageAmount;
	if (Node.Health < 0)
		Node.DisableObjective(Instigator);
	else if (bAttackNotification) {
		//attack notification
		if (Node.LastAttackMessageTime + 1 < C.Level.TimeSeconds) {
			if (Node.bFinalCore) {
				if (float(Node.Health) / Node.DamageCapacity > 0.55)
					Node.BroadcastLocalizedMessage(class'ONSOnslaughtMessage', 7 + Node.DefenderTeamIndex,,, Node);
				else if (float(Node.Health) / Node.DamageCapacity > 0.45)
					Node.BroadcastLocalizedMessage(class'ONSOnslaughtMessage', 25 + Node.DefenderTeamIndex,,, Node);
				else
					Node.BroadcastLocalizedMessage(class'ONSOnslaughtMessage', 18 + Node.DefenderTeamIndex,,, Node);
			}
			else
				Node.BroadcastLocalizedMessage(class'ONSOnslaughtMessage', 9 + Node.DefenderTeamIndex,,, Node);
			UnrealTeamInfo(C.Level.GRI.Teams[Node.DefenderTeamIndex]).AI.CriticalObjectiveWarning(Node, Instigator);
			Node.LastAttackMessageTime = C.Level.TimeSeconds;
		}
		Node.LastAttackTime = C.Level.TimeSeconds;
	}

	return false;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	DamageAmount = 100
	bAttackNotification = True
}