OnslaughtSpecialsLiteV2.ACTION_HealPowerNode

/******************************************************************************
ACTION_HealNode

Creation date: 2010-08-26 17:38
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class ACTION_HealPowerNode extends ScriptedAction;


var() name NodeTag;
var() int HealAmount;
var() bool bWithEffect;

var ONSPowerCore Node;


function bool InitActionFor(ScriptedController C)
{
	if (Node == None && NodeTag != '') {
		foreach C.AllActors(class'ONSPowerCore', Node, NodeTag) {
			break;
		}
		if (Node == None) {
			log(C.SequenceScript@C.ActionNum@Name@"- No power node/core for tag '"$NodeTag$"'");
			NodeTag = '';
		}
	}

	if (Node == None || Node.Health == 0 || Node.Health == Node.DamageCapacity || HealAmount <= 0 || Node.CoreStage != 0 && Node.CoreStage != 2)
		return false;

	if (bWithEffect && Node.IsA('ONSPowerNodeSpecial')) {
		Node.HealDamage(HealAmount, None, None);
	}
	else {
		Node.Health = Min(Node.Health + HealAmount, Node.DamageCapacity);
		Node.NetUpdateTime = C.Level.TimeSeconds - 1;
	}

	if (Node.Health == Node.DamageCapacity && C.Level.TimeSeconds - Node.HealingTime < 0.5)
		Node.PlaySound(Node.HealedSound, SLOT_Misc, 5.0);
	return false;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	HealAmount = 10
}