OnslaughtSpecialsLiteV2.ONSSwitchedSidesEventRedirector

/******************************************************************************
ONSSwitchedSidesEventRedirector

Creation date: 2010-08-22 15:41
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class ONSSwitchedSidesEventRedirector extends Triggers;


//=============================================================================
// Imports
//=============================================================================

#exec texture import file=Textures\S_SideSwitchRedirect.bmp masked=1


//=============================================================================
// Properties
//=============================================================================

/** Event to trigger instead of Event if sides are switched. */
var(Events) name SwitchedSidesEvent;


function bool SidesAreSwitched()
{
	return ONSOnslaughtGame(Level.Game) != None && ONSOnslaughtGame(Level.Game).bSidesAreSwitched;
}

function Trigger(Actor Origin, Pawn Causer)
{
	if (SidesAreSwitched())
		TriggerEvent(SwitchedSidesEvent, Origin, Causer);
	else
		TriggerEvent(Event, Origin, Causer);
}


function UnTrigger(Actor Origin, Pawn Causer)
{
	if (SidesAreSwitched())
		UnTriggerEvent(SwitchedSidesEvent, Origin, Causer);
	else
		UnTriggerEvent(Event, Origin, Causer);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	bCollideActors = False
	Texture = S_SideSwitchRedirect
}