OnslaughtSpecialsLiteV2.ONSWithTranslocator

/******************************************************************************
Forcibly enables the translocator in this map. Can be disabled for specific
link setups via link setup supplements.

Creation date: 2010-08-22 10:30
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class ONSWithTranslocator extends Info placeable;


/**
Hooks into player spawning by capturing PlayerStart events.
*/
function BeginPlay()
{
	local PlayerStart PS;
	local array<name> EventNames;
	local int i;

	Tag = ''; // ensure not triggered directly

	foreach AllActors(class'PlayerStart', PS) {
		// ensure event is set to something
		if (PS.Event == '')
			PS.Event = Class.Name;

		// find already captured event names
		i = -1;
		do {} until (++i == EventNames.Length || EventNames[i] == PS.Event);

		if (i == EventNames.Length) {
			// event not captured yet
			EventNames[EventNames.Length] = PS.Event;
			Spawn(class'ONSSpecialEventForwarder', Self, PS.Event);
		}
	}
}


function Trigger(Actor PlayerStart, Pawn SpawnedPlayer)
{
	if (SpawnedPlayer == None)
		return;

	//log("Adding Translocator to"@SpawnedPlayer.PlayerReplicationInfo.PlayerName, Class.Name);
	SpawnedPlayer.CreateInventory("XWeapons.TransLauncher");
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
}