OnslaughtSpecialsLiteV2.TriggeredWeaponBase

/******************************************************************************
TriggeredWeaponBase

Creation date: 2010-08-22 13:24
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class TriggeredWeaponBase extends xWeaponBase;


/** Should the weapon respawn automatically after being picked up? */
var() bool bShouldRespawn;


simulated function PostBeginPlay()
{
	if (WeaponType == None) {
		InitialState = '';
		PowerUp = None;
		return;
	}
	if (Level.NetMode != NM_Client && Tag != '' && bStatic) {
		// static actors aren't triggered, so use event forwarder
		Spawn(class'ONSSpecialEventForwarder', Self, Tag);
		Tag = ''; // to prevent accidental double triggering
	}

	PowerUp = WeaponType.default.PickupClass;

	if (PowerUp != None) {
		if (myMarker != None)
			myMarker.bSuperPickup = WeaponType.default.InventoryGroup == 0;

		if (Level.NetMode != NM_DedicatedServer)
			PowerUp.static.StaticPrecache(Level);
	}

	if (!bHidden && Level.NetMode != NM_DedicatedServer)
		myEmitter = Spawn(SpiralEmitter,,, Location + vect(0,0,1) * SpawnHeight);
}


/**
Get rid of the pickup with proper visual effects.
*/
function FadeOutPickup()
{
	if (myPickup != None) {
		if (myPickup.IsInState('Sleeping')) {
			// still spawning
			myPickup.Destroy();
		}
		else
			myPickup.GotoState('FadeOut');

		myPickup = None;
	}
}


/**
Triggering ensures the weapon is spawned, reset removes it.
*/
auto state() TriggerTurnOn
{
	function Reset()
	{
		if (myPickup != None)
			myPickup.Destroy();
	}

	function Trigger(Actor Origin, Pawn Causer)
	{
		if (myPickUp == None)
			SpawnPickup();

		if (myPickUp != None) {
			// play respawn effect
			if (bDelayedSpawn)
				myPickUp.GotoState('Sleeping', 'DelayedSpawn');
			else
				myPickUp.GotoState('Sleeping', 'Respawn');
			if (!bShouldRespawn)
				myPickUp.RespawnTime = 0; // destroy after picked up
		}
	}
}


/**
Triggering ensures the weapon is spawned, untrigger or reset ensures it's gone.
*/
state() TriggerControl extends TriggerTurnOn
{
	function UnTrigger(Actor Origin, Pawn Causer)
	{
		FadeOutPickup();
	}
}


/**
Triggering spawns the weapon, triggering again or reset removes it.
*/
state() TriggerToggle extends TriggerTurnOn
{
	function Trigger(Actor Origin, Pawn Causer)
	{
		if (myPickup != None)
			FadeOutPickup();
		else
			Super.Trigger(Origin, Causer);
	}
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	InitialState = TriggerControl

	Skins      = ()
	StaticMesh = 2k4chargerMESHES.WeaponChargerMESH-DS
	PrePivot   = (Z=3.7)
	DrawScale  = 0.5
}