OnslaughtSpecialsLiteV2.xTeamMonitor

/******************************************************************************
xTeamMonitor

Creation date: 2010-07-07 10:32
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class xTeamMonitor extends xTeamBanner hidecategories(xTeamBanner);


//=============================================================================
// Properties
//=============================================================================

/** Monitor screen material for red team. */
var() Material RedTeamShader;

/** Monitor screen material for blue team. */
var() Material BlueTeamShader;

/** Neutral monitor screen material. */
var() Material NeutralShader;

/** Disabled monitor screen material. */
var() Material DisabledShader;

/**
Combiners to apply the team symbols to.
The symbol material is applied to Material2.
*/
var() Combiner TeamSymbolCombiners[2];

/** Index of the Skins slot the team material is applied to. */
var() byte TeamSkinIndex;


simulated function UpdatePrecacheMaterials()
{
	Level.AddPrecacheMaterial(RedTeamShader);
	Level.AddPrecacheMaterial(BlueTeamShader);
	Level.AddPrecacheMaterial(NeutralShader);

	super.UpdatePrecacheMaterials();
}


simulated function PostBeginPlay()
{
	Super(Decoration).PostBeginPlay();
}


simulated function UpdateForTeam()
{
	switch (Team) {
	case 0:
		Skins[TeamSkinIndex] = RedTeamShader;
		break;
	case 1:
		Skins[TeamSkinIndex] = BlueTeamShader;
		break;
	case 255:
		Skins[TeamSkinIndex] = DisabledShader;
		break;
	default:
		Skins[TeamSkinIndex] = NeutralShader;
	}
	
	if (GRI != None && Team < 2 && GRI.TeamSymbols[Team] != None && TeamSymbolCombiners[Team] != None)
		TeamSymbolCombiners[Team].Material2 = GRI.TeamSymbols[Team];
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	DrawType       = DT_StaticMesh
	Mesh           = None
	bUnlit         = False
	bProjTarget    = True
	bCollideActors = True
	bBlockActors   = True
	bBlockKarma    = True
	bWorldGeometry = True
	
	RedTeamShader  = Shader'XGameTextures.SuperPickups.RedScreenS'
	BlueTeamShader = Shader'XGameTextures.SuperPickups.BlueScreenS'
	NeutralShader  = Shader'XGameTextures.SuperPickups.GreyScreenS'
	DisabledShader = Shader'XGameTextures.SuperPickups.BlackScreenS'
	
	TeamSymbolCombiners[0] = Combiner'XGameTextures.SuperPickups.RedTeamScreenC'
	TeamSymbolCombiners[1] = Combiner'XGameTextures.SuperPickups.BlueTeamScreenC'
}