OnslaughtSpecialsLiteV2.xTeamMaterialSwitch

/******************************************************************************
xTeamMaterialSwitch

Creation date: 2010-07-07 10:30
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class xTeamMaterialSwitch extends xTeamBanner hidecategories(xTeamBanner);


//=============================================================================
// Properties
//=============================================================================

/** A MaterialSwitch with 4 materials: red, blue, neutral and disabled */
var() editconst editinline export MaterialSwitch MaterialSwitch; // editinline+export = create copy of subobject

/**
Combiners to apply the team symbols to.
The symbol material is applied to Material2.
*/
var() Combiner TeamSymbolCombiners[2];


simulated function PostBeginPlay()
{
	Super(Decoration).PostBeginPlay();
}


simulated function UpdateForTeam()
{
	MaterialSwitch.Current = Min(Team, MaterialSwitch.Materials.Length - 1);
	MaterialSwitch.Material = MaterialSwitch.Materials[MaterialSwitch.Current];
	
	if (GRI != None && Team < 2 && GRI.TeamSymbols[Team] != None && TeamSymbolCombiners[Team] != None)
		TeamSymbolCombiners[Team].Material2 = GRI.TeamSymbols[Team];
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	DrawType       = DT_Sprite
	Texture        = Texture'Engine.S_MaterialTrigger'
	Mesh           = None
	bCollideActors = False
	bHidden        = True
	
	Begin Object Class=ConstantColor Name=RedTeamColor
		Color = (R=255,G=0,B=0,A=255)
	End Object
	
	Begin Object Class=ConstantColor Name=BlueTeamColor
		Color = (R=32,G=64,B=255,A=255)
	End Object
	
	Begin Object Class=ConstantColor Name=NeutralColor
		Color = (R=192,G=192,B=192,A=255)
	End Object
	
	Begin Object Class=ConstantColor Name=DisabledColor
		Color = (R=64,G=64,B=64,A=255)
	End Object
	
	Begin Object Class=MaterialSwitch Name=TeamSwitch
		Materials = (RedTeamColor,BlueTeamColor,NeutralColor,DisabledColor)
	End Object
	MaterialSwitch = MaterialSwitch'TeamSwitch'
}