RandomVoting.RandomVotingHandler

/******************************************************************************
RandomVotingHandler

Creation date: 2010-02-10 21:51
Last change: $Id$
Copyright (c) 2010, Günter
******************************************************************************/

class RandomVotingHandler extends xVotingHandler;


//=============================================================================
// Localization
//=============================================================================

var localized string lblAllowRandomVote;
var localized string descAllowRandomVote;

var localized string lblSkipRecentRandomMaps;
var localized string descSkipRecentRandomMaps;

var localized string lblRandomSuffix;
var localized string descRandomSuffix;


//=============================================================================
// Configuration
//=============================================================================

var config bool bAllowRandomVote;
var config bool bSkipRecentRandomMaps;
var config string RandomSuffix;


static function FillPlayInfo(PlayInfo PlayInfo)
{
	Super.FillPlayInfo(PlayInfo);

	PlayInfo.AddSetting(default.MapVoteGroup, "bAllowRandomVote", default.lblAllowRandomVote, 0, 1, "Check",,, True, True);
	PlayInfo.AddSetting(default.MapVoteGroup, "bSkipRecentRandomMaps", default.lblSkipRecentRandomMaps, 0, 1, "Check",,, True, True);
	PlayInfo.AddSetting(default.MapVoteGroup, "RandomSuffix", default.lblRandomSuffix, 0, 1, "Text", "20",, True, True);
}

static event bool AcceptPlayInfoProperty(string PropertyName)
{
	switch (PropertyName) {
	case "GameConfig":
		return false; // never! crashes if too large!

	default:
		return Super.AcceptPlayInfoProperty(PropertyName);
	}
}

static event string GetDescriptionText(string PropName)
{
	switch (PropName) {
	case "bAllowRandomVote":
		return default.descAllowRandomVote;
	case "bSkipRecentRandomMaps":
		return default.descSkipRecentRandomMaps;
	case "RandomSuffix":
		return default.descRandomSuffix;
	default:
		return Super.GetDescriptionText(PropName);
	}
}


function LoadMapList()
{
	local int i, j, k;
	local array<string> Prefixes, AllPrefixes;

	Super.LoadMapList();

	if (!bAllowRandomVote)
		return;

	log("Adding random vote to map list");
	for (i = 0; i < GameConfig.Length; ++i) {
		if (GameConfig[i].Prefix != "") {
			Split(Caps(GameConfig[i].Prefix), ",", Prefixes);
			for (j = 0; j < Prefixes.Length; ++j) {
				for (k = 0; k < AllPrefixes.Length && AllPrefixes[k] < Prefixes[j]; ++k);
				if (k == AllPrefixes.Length || AllPrefixes[k] > Prefixes[j]) {
					AllPrefixes.Insert(k, 1);
					AllPrefixes[k] = Prefixes[j];
				}
			}
		}
	}

	MapList.Insert(0, AllPrefixes.Length);
	for (i = 0; i < AllPrefixes.Length; ++i) {
		MapList[i].MapName = AllPrefixes[i] $ RandomSuffix;
		MapList[i].bEnabled = True;
	}
	MapCount += AllPrefixes.Length;
}

function string SetupGameMap(MapVoteMapList MapInfo, int GameIndex, MapHistoryInfo MapHistoryInfo)
{
	local string ReturnString, Prefix;
	local string MutatorString;
	local string OptionString;
	local array<string> EnabledMaps;
	local int i, SuffixLen, PrefixLen;

	// Add Per-GameType Mutators
	if (GameConfig[GameIndex].Mutators != "")
		MutatorString = MutatorString $ GameConfig[GameIndex].Mutators;

	// Add Per-Map Mutators
	if (MapHistoryInfo.U != "")
		MutatorString = MutatorString $ "," $ MapHistoryInfo.U;

	// Add Per-GameType Game Options
	if (GameConfig[GameIndex].Options != "")
		OptionString = OptionString $ Repl(Repl(GameConfig[GameIndex].Options,",","?")," ","");

	// Add Per-Map Game Options
	if (MapHistoryInfo.G != "")
		OptionString = OptionString $ "?" $ MapHistoryInfo.G;

	// create URL
	ReturnString = MapInfo.MapName; //$ ".ut2";
	SuffixLen = Len(RandomSuffix);
	if (Right(ReturnString, SuffixLen) ~= RandomSuffix) {
		Prefix = Left(ReturnString, Len(ReturnString) - SuffixLen);
		PrefixLen = Len(Prefix);
		// it's the "random" entry
		for (i = 0; i < MapList.Length; ++i) {
			if ((MapList[i].bEnabled || !bSkipRecentRandomMaps) && Right(MapList[i].MapName, SuffixLen) != RandomSuffix && Left(MapList[i].MapName, PrefixLen) ~= Prefix)
				EnabledMaps[EnabledMaps.Length] = MapList[i].MapName;
		}
		if (EnabledMaps.Length == 0) {
			// no enabled maps available, pick from disabled maps
			for (i = 0; i < MapList.Length; ++i) {
				if (Right(MapList[i].MapName, SuffixLen) != RandomSuffix && Left(MapList[i].MapName, PrefixLen) ~= Prefix)
					EnabledMaps[EnabledMaps.Length] = MapList[i].MapName;
			}
		}
		ReturnString = EnabledMaps[Rand(EnabledMaps.Length)];
	}
	ReturnString = ReturnString $ "?Game=" $ GameConfig[GameIndex].GameClass;

	if (MutatorString != "")
		ReturnString = ReturnString $ "?Mutator=" $ MutatorString;

	if (OptionString != "")
		ReturnString = ReturnString $ "?" $ OptionString;

	return ReturnString;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	bAllowRandomVote = True
	bSkipRecentRandomMaps = True
	RandomSuffix     = "-<???>"

	lblAllowRandomVote  = "Allow random map vote"
	descAllowRandomVote = "Add a special entry to the vote map list that will pick a random map list entry if voted for."

	lblSkipRecentRandomMaps  = "Skip recent maps for random vote"
	descSkipRecentRandomMaps = "Prevent recently voted maps from being picked as result of the random vote."

	lblRandomSuffix  = "Random vote suffix"
	descRandomSuffix = "Map name suffix for the random vote entry in the map list."
}