UTANBanManager104.BanDatabase

/******************************************************************************
Stores bans in an INI file.

Creation date: 2010-03-31 18:24
Last change: $Id$
Copyright (c) 2010-2011, Wormbo
******************************************************************************/

class BanDatabase extends UTANBanDatabase within UTANBanDatabase config perobjectconfig dependson(MutUTAN);


struct TEntry {
	var config int ID;
	var config string GUID;
	var config string IP;
	var config bool Remote;
	var config bool Exclude;
	var config bool Cheater;
	var config bool Disabled;
};

var config array<TEntry> Entry;


function int GetNumEntries()
{
	return Entry.Length;
}

function ClearEntries()
{
	Entry.Length = 0;
	BanReasons.Length = 0;
	SortedReasons.Length = 0;
}

function MutUTAN.TListEntry GetEntry(int Index)
{
	local MutUTAN.TListEntry Result;

	Result.ID          = Entry[Index].ID;
	Result.GUID        = class'MutUTAN'.static.StringToGuid(Entry[Index].GUID);
	Result.IP          = class'MutUTAN'.static.StringToCidr(Entry[Index].IP);
	Result.bIsRemote   = Entry[Index].Remote;
	Result.bIsExclude  = Entry[Index].Exclude;
	Result.bIsCheater  = Entry[Index].Cheater;
	Result.bIsDisabled = Entry[Index].Disabled;

	return Result;
}


function int AddEntry(MutUTAN.TListEntry ListEntry)
{
	local int i;

	i = Entry.Length;
	Entry.Length = i + 1;
	Entry[i].ID       = ListEntry.ID;
	Entry[i].GUID     = class'MutUTAN'.static.GuidToString(ListEntry.GUID);
	Entry[i].IP       = class'MutUTAN'.static.CidrToString(ListEntry.IP);
	Entry[i].Remote   = ListEntry.bIsRemote;
	Entry[i].Exclude  = ListEntry.bIsExclude;
	Entry[i].Cheater  = ListEntry.bIsCheater;
	Entry[i].Disabled = ListEntry.bIsDisabled;

	return i;
}

function bool SaveDatabase(LevelInfo Level, string BanDatabaseName)
{
	SaveConfig();
	return true;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
}