UTPlusStandaloneHitSounds.UTPlusHitSounds

/******************************************************************************
UTPlusHitSounds

Creation date: 2011-08-29 11:08
Last change: $Id$
Copyright © 2011, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class UTPlusHitSounds extends GameRules;


//=============================================================================
// Variables
//=============================================================================

var bool bAllowVariableHitSounds;
var bool bLineOfSightHitSounds;
var bool bObjectiveHitSounds;

/** List of hit sound replicators. */
var UTPlusHitSoundTag firstTagHitSound;

// Hit sound replicators are spawned in FindPlayerStart().
// These vars help reducing the number of checks.
var float LastFindStartTime;
var Controller LastFindStartPlayer;


static function UTPlusHitSounds FindFor(LevelInfo Level)
{
	local GameRules GR;

	if (Level.Game != None) {
		for (GR = Level.Game.GameRulesModifiers; GR != None; GR = GR.NextGameRules) {
			if (UTPlusHitSounds(GR) != None)
				return UTPlusHitSounds(GR);
		}
	}
	return None;
}


function PostBeginPlay()
{
	local array<name> NodeEvents;
	local DestroyableObjective O;
	local UTPlusEventForwarder EF;
	local int i;

	bAllowVariableHitSounds = class'MutUTPlusHitSounds'.default.bAllowVariableHitSounds;
	bLineOfSightHitSounds   = class'MutUTPlusHitSounds'.default.bLineOfSightHitSounds;
	bObjectiveHitSounds     = class'MutUTPlusHitSounds'.default.bObjectiveHitSounds;

	Level.Game.AddGameModifier(Self);
	AddtoPackageMap(string(Class.Outer));

	if (bObjectiveHitSounds) {
		// sweet little hack
		foreach AllActors(class'DestroyableObjective', O) {
			if (O.TakeDamageEvent == '')
				O.TakeDamageEvent = 'UTPlusObjectiveTakeDamage';
			O.DamageEventThreshold = Max(O.DamageEventThreshold, 1);

			for (i = 0; i < NodeEvents.Length; ++i) {
				if (NodeEvents[i] == O.TakeDamageEvent)
					break;
			}
			if (i == NodeEvents.Length) {
				NodeEvents[i] = O.TakeDamageEvent;
				EF = Spawn(class'UTPlusEventForwarder',, O.TakeDamageEvent);
				EF.OnTrigger = CalcObjectiveDamage;
			}
		}
	}
}


/**
Ensure the player has a hit sound replicator.
*/
/*
function NavigationPoint FindPlayerStart(Controller Player, optional byte InTeam, optional string IncomingName)
{
	if (Player != None && Player.PlayerReplicationInfo != None && (LastFindStartTime != Level.TimeSeconds || LastFindStartPlayer != Player)) {
		LastFindStartTime = Level.TimeSeconds;
		LastFindStartPlayer = Player;
		class'UTPlusHitSoundTag'.static.SpawnFor(Player.PlayerReplicationInfo);
	}
	return Super.FindPlayerStart(Player, InTeam, IncomingName);
}
*/


/**
Check for HitSound damage and add momentum to miniguns and linkguns.
*/
function int NetDamage(int OriginalDamage, int Damage, Pawn Injured, Pawn InstigatedBy, vector HitLocation, out vector Momentum, class<DamageType> DamageType)
{
	local Controller InstigatorController;
	local byte InjuredTeam;

	Damage = Super.NetDamage(OriginalDamage, Damage, Injured, InstigatedBy, HitLocation, Momentum, DamageType);

	if (InstigatedBy != None && Injured != None && InstigatedBy != Injured && InstigatedBy.Health > 0) {
		InstigatorController = InstigatedBy.Controller;
		if (InstigatorController == None && DamageType != None && DamageType.default.bDelayedDamage) {
			InstigatorController = Injured.DelayedDamageInstigatorController;
		}
		if (InstigatorController != None) {
			if (Injured.Controller != None)
				InjuredTeam = Injured.Controller.GetTeamNum();
			else if (Vehicle(Injured) != None)
				InjuredTeam = Vehicle(Injured).Team;
			else
				InjuredTeam = 255;
			if (Level.Game.IsOnTeam(InstigatorController, InjuredTeam)) {
				// original damage for friendly-fire
				CalcHitSoundsFor(InstigatorController, OriginalDamage, Injured);
			}
			else {
				// actual damage in all other cases
				CalcHitSoundsFor(InstigatorController, Damage, Injured);
			}
		}
	}
	return Damage;
}

/**
Plays a hit sound on the player.
*/
function CalcHitSoundsFor(Controller Player, int Damage, Pawn Victim)
{
	local UTPlusHitSoundTag PlayerTag;

	if (Player == None || Player.PlayerReplicationInfo == None || Damage < 0 || Victim == None || Victim.Health <= 0 || bLineOfSightHitSounds && !Player.LineOfSightTo(Victim)) {
		// ignore this hit
		return;
	}

	PlayerTag = class'UTPlusHitSoundTag'.static.SpawnFor(Player.PlayerReplicationInfo);
	if (PlayerTag != None)
		PlayerTag.AddDamage(Damage, Victim);

	if (TimerRate == 0)
		SetTimer(0.05, false);
}


function CalcObjectiveDamage(Actor Damaged, Pawn Attacker)
{
	local DestroyableObjective Objective;
	local UTPlusHitSoundTag PlayerTag;

	Objective = DestroyableObjective(Damaged);
	if (Attacker != None && Attacker.PlayerReplicationInfo != None)
		PlayerTag = class'UTPlusHitSoundTag'.static.SpawnFor(Attacker.PlayerReplicationInfo);
	if (Objective == None || Objective.AccumulatedDamage <= 0 || PlayerTag == None)
		return;
	PlayerTag.AddObjectiveDamage(Objective);

	if (TimerRate == 0)
		SetTimer(0.05, false);
}


event Timer()
{
	local UTPlusHitSoundTag PlayerTag;

	for (PlayerTag = firstTagHitSound; PlayerTag != None; PlayerTag = PlayerTag.nextTag) {
		PlayerTag.DispatchHitSound(bAllowVariableHitSounds);
	}
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	bAllowVariableHitSounds = True
	bLineOfSightHitSounds   = True
	bObjectiveHitSounds     = True
}