WormbotHandler3SPN.WIR_GameHandler_TAM

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Handler for Team Arena Master.
******************************************************************************/


class WIR_GameHandler_TAM extends WIR_GameHandler_DM;


//=============================================================================
// Localization
//=============================================================================

var localized string MsgPlayerWonRound;
var localized string MsgDarkHorse;


//== HandleLocalizedMessage ===================================================
/**
Skip the pointless "player is OUT" messages.
*/
//=============================================================================

function bool HandleLocalizedMessage(class<LocalMessage> Message, int Switch, PlayerReplicationInfo RelatedPRI_1, PlayerReplicationInfo RelatedPRI_2, Object OptionalObject)
{
  local string Msg;
  
  if ( MyMutator != None && MyMutator.ReportConnection != None ) {
    if ( Message.Name == 'Message_PlayerIsOut_3SPN' || Message.Name == 'Message_GameLost_3SPN' )
      return true;
    
    if ( Message.Name == 'Message_Darkhorse_3SPN' ) {
      Msg = Repl(MsgDarkHorse, "%r", GetRemainingTime(), True);
      Msg = Repl(Msg, "%p", FormatPlayerName(RelatedPRI_1), True);
      MyMutator.ReportConnection.SendMessage(Msg);
      
      return true;
    }
    
    if ( Message.Name == 'Message_RoundLost_3SPN' ) {
      Msg = Repl(MsgPlayerWonRound, "%r", GetRemainingTime(), True);
      Msg = Repl(Msg, "%p", FormatPlayerName(RelatedPRI_1), True);
      MyMutator.ReportConnection.SendMessage(Msg);
      
      return true;
    }
  }
  
  return Super.HandleLocalizedMessage(Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
}


//== AddRow ==================================================================
/**
Adds data in a row on the left or right side of the scoreboard table.
*/
//=============================================================================

function AddRow(out array<WIR_Util.TAlignedTable> Table, int row, PlayerReplicationInfo PRI, bool bRightSide)
{
  local int col, coloffset;
  
  if ( bRightSide )
    coloffset = (Table.Length + 1) / 2;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = Repl(FormatPlayerName(PRI, True), "[^B]", "", True); // strip code for bold
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.Score));
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.Deaths));
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = int(PRI.GetPropertyText("Percent")) $ "%";
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.GetPropertyText("WeaponDamage")));
  ++col;
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
  MsgPlayerWonRound = "[^B][%r][^B] %p[^O] wins the round"
  MsgDarkHorse      = "[%r] - %p[^O] is a [^B]Dark Horse[^B]"
  
  StringTableHeader(0)  = "[^U]Name"
  StringTableHeader(1)  = "Score"
  StringTableHeader(2)  = "Deaths"
  StringTableHeader(3)  = "Acc."
  StringTableHeader(4)  = "Dam.[^O]"
  StringTableHeader(5)  = " "
  StringTableHeader(6)  = "[^U]Name"
  StringTableHeader(7)  = "Score"
  StringTableHeader(8)  = "Deaths"
  StringTableHeader(9)  = "Acc."
  StringTableHeader(10) = "Dam.[^O]"
  
  ColumnAlign(0)  = TXTA_Left
  ColumnAlign(1)  = TXTA_Right
  ColumnAlign(2)  = TXTA_Right
  ColumnAlign(3)  = TXTA_Right
  ColumnAlign(4)  = TXTA_Right
  ColumnAlign(5)  = TXTA_Center
  ColumnAlign(6)  = TXTA_Left
  ColumnAlign(7)  = TXTA_Right
  ColumnAlign(8)  = TXTA_Right
  ColumnAlign(9)  = TXTA_Right
  ColumnAlign(10) = TXTA_Right
  
  HandlerGroup = "Wormbot (TAM)"
  bAnnounceOutOfLives = False
  StringScoreTemplate = "[score]/[percent]%/[weapondamage]/[ping]ms"
}