WormbotHandler3SPNv3.WIR_GameHandler_AMv3

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Handler for Arena Master.
******************************************************************************/


class WIR_GameHandler_AMv3 extends WIR_GameHandler_TAMv3;


//== AddRow ==================================================================
/**
Adds data in a row on the left or right side of the scoreboard table.
*/
//=============================================================================

function AddRow(out array<WIR_Util.TAlignedTable> Table, int row, PlayerReplicationInfo PRI, bool bRightSide)
{
  local int col, coloffset;
  
  if ( bRightSide )
    coloffset = (Table.Length + 1) / 2;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = Repl(FormatPlayerName(PRI, True), "[^B]", "", True); // strip code for bold
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.GetPropertyText("RoundsWon")));
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.Score % 10000));
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = int(PRI.GetPropertyText("AveragePercent")) $ "%";
  ++col;
  
  if ( Table[col+coloffset].Rows.Length <= row )
    Table[col+coloffset].Rows.Length = row + 1;
  Table[col+coloffset].Rows[row].Content = string(int(PRI.GetPropertyText("EnemyDamage")));
  ++col;
}


//== InOrder ==================================================================
/**
Returns True if player 1 ranks higher than player 2.
*/
//=============================================================================

function bool InOrder(PlayerReplicationInfo PRI1, PlayerReplicationInfo PRI2)
{
  if ( PRI1 == None || PRI2 == None )
    return PRI1 != None;
  
  if ( PRI1.Score % 10000 > PRI2.Score % 10000 )
    return true;
  if ( PRI1.Score % 10000 < PRI2.Score % 10000 )
    return false;
  
  if ( PRI1.Score > PRI2.Score )
    return true;
  if ( PRI1.Score < PRI2.Score )
    return false;
  
  if ( PRI1.Deaths < PRI2.Deaths )
    return true;
  if ( PRI1.Deaths > PRI2.Deaths )
    return false;
  
  return PRI1.PlayerName > PRI2.PlayerName;
}


//== FormatPlayerName =========================================================
/**
Returns a formatted player name for IRC.
*/
//============================================================================= 

function string FormatPlayerName(Actor Player, optional bool bOnlyName, optional string StringScoreTemplate, optional out string CustomPrefix)
{
  local PlayerReplicationInfo PRI;
  local Controller C;
  local Pawn P;
  
  class'WIR_Util'.static.GetPlayerActors(Player, C, P, PRI);
  
  StringScoreTemplate = Repl(StringScoreTemplate, "[score]", string(int(PRI.Score % 10000)));
  StringScoreTemplate = Repl(StringScoreTemplate, "[roundswon]", string(int(PRI.Score / 10000)));
  return Super.FormatPlayerName(Player, bOnlyName, StringScoreTemplate, CustomPrefix);
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
  StringTableHeader(0)  = "[^U]Name"
  StringTableHeader(1)  = "Wins"
  StringTableHeader(2)  = "Score"
  StringTableHeader(3)  = "Acc."
  StringTableHeader(4)  = "Dam.[^O]"
  StringTableHeader(5)  = " "
  StringTableHeader(6)  = "[^U]Name"
  StringTableHeader(7)  = "Wins"
  StringTableHeader(8)  = "Score"
  StringTableHeader(9)  = "Acc."
  StringTableHeader(10) = "Dam.[^O]"
  
  ColumnAlign(0)  = TXTA_Left
  ColumnAlign(1)  = TXTA_Right
  ColumnAlign(2)  = TXTA_Right
  ColumnAlign(3)  = TXTA_Right
  ColumnAlign(4)  = TXTA_Right
  ColumnAlign(5)  = TXTA_Center
  ColumnAlign(6)  = TXTA_Left
  ColumnAlign(7)  = TXTA_Right
  ColumnAlign(8)  = TXTA_Right
  ColumnAlign(9)  = TXTA_Right
  ColumnAlign(10) = TXTA_Right
  
  HandlerGroup = "Wormbot (AMv3)"
  StringScoreTemplate = "[roundswon]/[score]/[EnemyDamage]/[ping]ms"
}