WormbotReporter.WIR_GameRules

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Catches score and pickup notifications.
******************************************************************************/


class WIR_GameRules extends GameRules;


//=============================================================================
// Variables
//=============================================================================

var MutWormbot MyMutator;

var struct TPendingKill {
  var Pawn Killed;
  var Controller Killer;
  var class<DamageType> DamageType;
  var vector HitLocation;
} PendingKill;


//== PostBeginPlay ============================================================
/**
Register the GameRules actor and initialize it.
*/
//=============================================================================

event PostBeginPlay()
{
  Level.Game.AddGameModifier(Self);
  MyMutator = MutWormbot(Owner);
}


//== CheckEndGame =============================================================
/**
Remeber the end game reason.
*/
//=============================================================================

function bool CheckEndGame(PlayerReplicationInfo Winner, string Reason)
{
  local bool bHandleEndGame;
  
  bHandleEndGame = Super.CheckEndGame(Winner, Reason);
  MyMutator.GameEndReason = Reason;
  return bHandleEndGame;
}


//== ScoreKill ================================================================
/**
Report a kill.
*/
//=============================================================================

function ScoreKill(Controller Killer, Controller Killed)
{
  if ( MyMutator != None && Killed != None ) {
    if ( PendingKill.Killer == Killer && PendingKill.Killed != None && Killed.Pawn == PendingKill.Killed )
      MyMutator.ScoreKill(Killer, Killed, PendingKill.DamageType);
    else
      MyMutator.ScoreKill(Killer, Killed);
  }
  Super.ScoreKill(Killer, Killed);
}


//== PreventDeath =============================================================
/**
Capture the damage type for a potential score kill.
*/
//=============================================================================

function bool PreventDeath(Pawn Killed, Controller Killer, class<DamageType> DamageType, vector HitLocation)
{
  PendingKill.Killed      = Killed;
  PendingKill.Killer      = Killer;
  PendingKill.DamageType  = DamageType;
  PendingKill.HitLocation = HitLocation;
  
  return Super.PreventDeath(Killed, Killer, DamageType, HitLocation);
}


//== ScoreObjective ===========================================================
/**
Report a goal, capture, etc.
*/
//=============================================================================

function ScoreObjective(PlayerReplicationInfo Scorer, int Score)
{
  if ( MyMutator != None && class'WIR_Util'.static.IsPlayer(Scorer) )
    MyMutator.ScoreObjective(Controller(Scorer.Owner), Score);
  
  Super.ScoreObjective(Scorer, Score);
}


//== OverridePickupQuery ======================================================
/**
Report a pickup.
*/
//=============================================================================

function bool OverridePickupQuery(Pawn Other, Pickup Item, out byte bAllowPickup)
{
  if ( MyMutator != None && MyMutator.MyGameHandler != None && MyMutator.MyGameHandler.ReportPickups > 0
      && Other != None && class'WIR_Util'.static.IsPlayer(Other) ) {
    if ( Item.Event == class'Actor'.default.Event )
      Item.Event = MyMutator.Name;
    MyMutator.Tag = Item.Event;
  }
  return Super.OverridePickupQuery(Other, Item, bAllowPickup);
}