WormbotReporter.WIR_ModHandler

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Abstract base class for game, mutator and other mod handlers.
******************************************************************************/


class WIR_ModHandler extends Info
    abstract;


//=============================================================================
// Structs
//=============================================================================

struct TModHandler {
  var config string ActorClass;
  var config string Handler;
};


//=============================================================================
// Localization
//=============================================================================

var localized string HandlerGroup;
var localized string lblModHandler;
var localized string descModHandler;


//=============================================================================
// Configuration
//=============================================================================

var globalconfig array<TModHandler> ModHandler;


//=============================================================================
// Variables
//=============================================================================

var MutWormbot      MyMutator;
var WIR_ModHandler  NextHandler;
var bool            bMatchStarted;


//== PostBeginPlay ============================================================
/**
Initialize the handler.
*/
//=============================================================================

event PostBeginPlay()
{
  MyMutator = MutWormbot(Owner);
  //log("Spawned"@self@"for"@MyMutator);
  if ( MyMutator == None )
    Error("Not spawned by Wormbot mutator!");
}


//== AddHandler ===============================================================
/**
Adds another handler.
*/
//=============================================================================

function AddHandler(WIR_ModHandler NewHandler)
{
  if ( NewHandler == Self )
    warn("Attempt to add the same handler twice");
  else if ( NextHandler != None )
    NextHandler.AddHandler(NewHandler);
  else
    NextHandler = NewHandler;
}


//== Destroyed ================================================================
/**
Unregister the handler.
*/
//=============================================================================

event Destroyed()
{
  local WIR_ModHandler Handler;
  
  if ( MyMutator.MyGameHandler == Self ) {
    warn("GameHandler"@self@"destroyed");
    MyMutator.MyGameHandler = WIR_GameHandler(NextHandler);
  }
  else {
    for (Handler = MyMutator.MyGameHandler; Handler != None; Handler = Handler.NextHandler)
      if ( Handler.NextHandler == Self )
        Handler.NextHandler = NextHandler;
  }
}


//== MatchStarting ============================================================
/**
Called by the GameInfo when the match starts.
*/
//============================================================================= 

function MatchStarting()
{
  bMatchStarted = True;
}


//== CriticalPlayer ===========================================================
/**
Called when the match starts.
*/
//============================================================================= 

function bool CriticalPlayer(Controller Player)
{
  if ( NextHandler != None )
    return NextHandler.CriticalPlayer(Player);
  
  return false;
}


//== GetRemainingTime =========================================================
/**
Returns the time remaining in the match or the time elapsed if there's no time limit.
*/
//============================================================================= 

function string GetRemainingTime()
{
  if ( NextHandler != None )
    return NextHandler.GetRemainingTime();
  
  return "";
}


//== HandleEndGame ============================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleEndGame(out string Reason)
{
  if ( NextHandler != None )
    return NextHandler.HandleEndGame(Reason);
  
  return false;
}


//== HandleNewRound ===========================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleNewRound()
{
  if ( NextHandler != None )
    return NextHandler.HandleNewRound();
  
  return false;
}


//== HandleEndRound ===========================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleEndRound(out string Reason)
{
  if ( NextHandler != None )
    return NextHandler.HandleEndRound(Reason);
  
  return false;
}


//== HandleKill ===============================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleKill(out Controller Killer, out Controller Killed, out class<DamageType> DamageType, out string MsgSuffix)
{
  if ( NextHandler != None )
    return NextHandler.HandleKill(Killer, Killed, DamageType, MsgSuffix);
  
  return false;
}


//== HandleStringMessage ======================================================
/**
Return True if the message was handled by the handler class.
*/
//=============================================================================

function bool HandleStringMessage(string Message, name Type)
{
  //log(Name@"HandleStringMessage"@Type@Message);
  if ( NextHandler != None )
    return NextHandler.HandleStringMessage(Message, Type);
  
  return false;
}


//== HandleLocalizedMessage ===================================================
/**
Return True if the message should not be reported through the default event.
*/
//=============================================================================

function bool HandleLocalizedMessage(class<LocalMessage> Message, int Switch, PlayerReplicationInfo RelatedPRI_1, PlayerReplicationInfo RelatedPRI_2, Object OptionalObject)
{
  if ( NextHandler != None )
    return NextHandler.HandleLocalizedMessage(Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
  
  if ( MyMutator == None || MyMutator.ReportConnection == None )
    return true;
  
  return false;
}


//== ScoreObjective ===========================================================
/**
Report a goal, capture, etc.
*/
//============================================================================= 

function ScoreObjective(Controller Scorer, int Score)
{
  if ( NextHandler != None )
    NextHandler.ScoreObjective(Scorer, Score);
}


//== UpdateLocationNames ======================================================
/**
Update the location names.
*/
//=============================================================================

function UpdateLocationNames()
{
  if ( NextHandler != None )
    NextHandler.UpdateLocationNames();
}


//== GetLocationNameFor =======================================================
/**
Returns true if LocName should be used as location name for the actor.
*/
//=============================================================================

function bool GetLocationNameFor(Actor A, out string LocName)
{
  if ( NextHandler != None )
    return NextHandler.GetLocationNameFor(a, LocName);
  
  return false;
}


//== GetObjectiveName =========================================================
/**
Returns a GameObjective's name.
*/
//=============================================================================

function string GetObjectiveName(GameObjective GO, optional bool bTeamColored)
{
  if ( NextHandler != None )
    return NextHandler.GetObjectiveName(GO, bTeamColored);
  
  return "";
}


//== GetObjectName ============================================================
/**
Returns a GameObject's name.
*/
//=============================================================================

function string GetObjectName(GameObject GO, optional bool bTeamColored)
{
  if ( NextHandler != None )
    return NextHandler.GetObjectName(GO, bTeamColored);
  
  return "";
}


//== FormatPlayerName =========================================================
/**
Returns a formatted player name for IRC.
*/
//============================================================================= 

function string FormatPlayerName(Actor Player, optional bool bOnlyName, optional string StringScoreTemplate, optional out string CustomPrefix)
{
  if ( NextHandler != None )
    return NextHandler.FormatPlayerName(Player, bOnlyName, StringScoreTemplate, CustomPrefix);
  
  return "";
}


//== FillPlayInfo =============================================================
/**
Add the configuration options to the PlayInfo.
*/
//=============================================================================

static function FillPlayInfo(PlayInfo PlayInfo)
{
  Super.FillPlayInfo(PlayInfo);
  //log("FillPlayInfo"@default.Class);
  PlayInfo.AddSetting(class'MutWormbot'.default.FriendlyName, "ModHandler", default.lblModHandler, 4, 100, "Text");
}


//== GetDescriptionText =======================================================
/**
Returns a description for the specified configuration option.
*/
//=============================================================================

static event string GetDescriptionText(string PropertyName)
{
  if ( PropertyName == "ModHandler" )
    return default.descModHandler;
  
  return Super.GetDescriptionText(PropertyName);
}


//== AcceptPlayInfoProperty ===================================================
/**
Returns whether a property may be added to the PlayInfo.
*/
//=============================================================================

static event bool AcceptPlayInfoProperty(string PropertyName)
{
  if ( PropertyName ~= "ModHandler" && default.Class != class'WIR_ModHandler' )
    return false;
	return Super.AcceptPlayInfoProperty(PropertyName);
}


//== Mutate ===================================================================
/**
Handle Mutate console commands.
*/
//============================================================================= 

function bool Mutate(string MutateString, PlayerController Sender)
{
  //log(Name@"Mutate"@Sender@MutateString);
  if ( NextHandler != None )
    return NextHandler.Mutate(MutateString, Sender);
  
  return false;
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
  ModHandler[0] = (ActorClass="MutAntiTCC",Handler="WormbotHandlerAntiTCC.WIR_ModHandler_AntiTCC")
  ModHandler[1] = (ActorClass="MutAntiTCCFinal",Handler="WormbotHandlerAntiTCC.WIR_ModHandler_AntiTCC")
  ModHandler[2] = (ActorClass="AntiTCC",Handler="WormbotHandlerAntiTCC.WIR_ModHandler_AntiTCC")
  ModHandler[3] = (ActorClass="MutUTComp",Handler="WormbotHandlerUTComp.WIR_ModHandler_UTComp")
  
  HandlerGroup  = "Wormbot Mod Handlers"
  
  lblModHandler   = "(Lists) Mod Handlers" 
  descModHandler  = "Configure mod handler classes." 
}