WVHoverTankV3.NekomataSecondaryTurret

/******************************************************************************
NekomataSecondaryTurret

Creation date: 2012-10-24 12:09
Last change: $Id$
Copyright © 2012, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class NekomataSecondaryTurret extends ONSTankSecondaryTurret;


//=============================================================================
// Imports
//=============================================================================

#exec audio import file=Sounds\humveegun1.wav name=GaussFire group=Nekomata


var() float DamageRadius;
var() float FireRecoilAmount;


function TraceFire(vector Start, rotator Dir)
{
	local vector X, End, HitLocation, HitNormal;
	local Actor Other;
	local ONSWeaponPawn WeaponPawn;
	local Vehicle VehicleInstigator;

	MaxRange();

	if (bDoOffsetTrace) {
		WeaponPawn = ONSWeaponPawn(Owner);
		if (WeaponPawn != None && WeaponPawn.VehicleBase != None) {
			if (!WeaponPawn.VehicleBase.TraceThisActor(HitLocation, HitNormal, Start, Start + vector(Dir) * (WeaponPawn.VehicleBase.CollisionRadius * 1.5)))
				Start = HitLocation;
		}
		else if (!Owner.TraceThisActor(HitLocation, HitNormal, Start, Start + vector(Dir) * (Owner.CollisionRadius * 1.5)))
			Start = HitLocation;
	}

	X = vector(Dir);
	End = Start + TraceRange * X;

	//skip past vehicle driver
	VehicleInstigator = Vehicle(Instigator);
	if (VehicleInstigator != None && VehicleInstigator.Driver != None) {
		VehicleInstigator.Driver.bBlockZeroExtentTraces = false;
		Other = Trace(HitLocation, HitNormal, End, Start, true);
		VehicleInstigator.Driver.bBlockZeroExtentTraces = true;
	}
	else
		Other = Trace(HitLocation, HitNormal, End, Start, True);

	if (Other != None && Other != Instigator) {
		ExtendedHurtRadius(HitLocation, X, Other);
		HitCount++;
		LastHitLocation = HitLocation;
		SpawnHitEffects(Other, HitLocation, HitNormal);
	}
	else {
		HitLocation = End;
		HitNormal = vect(0,0,0);
		HitCount++;
		LastHitLocation = HitLocation;
	}

	SpawnBeamEffect(Start, Dir, HitLocation, HitNormal, 0);

	if (Instigator != None)
	{
		if (Instigator.GetVehicleBase() != None)
			Instigator.GetVehicleBase().KAddImpulse(-FireRecoilAmount * vector(Dir), Start);
		else
			Instigator.KAddImpulse(-FireRecoilAmount * vector(Dir), Start);
	}
	NetUpdateTime = Level.TimeSeconds - 1;
}


state InstantFireMode
{
	simulated function SpawnHitEffects(Actor HitActor, vector HitLocation, vector HitNormal)
	{
		local PlayerController PC;

		if (Pawn(HitActor) == None || Vehicle(HitActor) != None)
			Super.SpawnHitEffects(HitActor, HitLocation, HitNormal);

		PC = Level.GetLocalPlayerController();
		if (PC != None && (Instigator != None && Instigator.Controller == PC || VSize(PC.ViewTarget.Location - HitLocation) < 10000))
			Spawn(class'GaussExplosionEffect',,, HitLocation + 10 * HitNormal);
	}
}


function ExtendedHurtRadius(vector HitLocation, vector AimDir, Actor HitActor)
{
	local Actor Victims;
	local float damageScale, dist, damageAmount;
	local vector dir, HL, HN;

	DamageAmount = RandRange(DamageMin, DamageMax);
	if (HitActor != None && HitActor != ONSWeaponPawn(Instigator).VehicleBase) {
		// first damage the hit actor
		dir = Normal(HitActor.Location - HitLocation);
		dir = Normal(dir + AimDir);
		HitActor.TakeDamage(DamageAmount, Instigator, HitActor.Location - 0.5 * (HitActor.CollisionHeight + HitActor.CollisionRadius) * dir, Momentum * dir, DamageType);
		if (Vehicle(HitActor) != None && Vehicle(HitActor).Health > 0)
			Vehicle(HitActor).DriverRadiusDamage(DamageAmount, DamageRadius, Instigator.Controller, DamageType, Momentum, HitLocation);
	}

	// now look for other nearby actors to damage
	foreach VisibleCollidingActors(class'Actor', Victims, DamageRadius + 500, HitLocation) {
		if (Victims != self && Victims != HitActor && Victims.Role == ROLE_Authority && !Victims.IsA('FluidSurfaceInfo')) {
			if (!Victims.TraceThisActor(HL, HN, DamageRadius * Normal(Victims.Location - HitLocation), HitLocation, vect(1,1,1) * Sqrt(DamageRadius)))
				HL = Victims.Location;
			dist = VSize(HL - HitLocation);
			if (dist > DamageRadius)
				continue;
			dir = Normal(Victims.Location - HitLocation);
			damageScale = 1 - FMax(0, dist / DamageRadius);
			Victims.TakeDamage(damageScale * DamageAmount, Instigator, Victims.Location - 0.5 * (Victims.CollisionHeight + Victims.CollisionRadius) * dir, damageScale * Momentum * dir, DamageType);
			if (Vehicle(Victims) != None && Vehicle(Victims).Health > 0)
				Vehicle(Victims).DriverRadiusDamage(DamageAmount, DamageRadius, Instigator.Controller, DamageType, Momentum, HitLocation);
		}
	}
}


simulated function Tick(float DeltaTime)
{
	if (Instigator != None && Instigator.PlayerReplicationInfo != None)
	{
		bForceCenterAim = False;
	}
	else if (!bActive && CurrentAim != rot(0,0,0))
	{
		bForceCenterAim = True;
		bActive = True;
	}
	else if (bActive && CurrentAim == rot(0,0,0))
	{
		bActive = False;
	}
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	RedSkin  = None
	BlueSkin = None
	Skins[0] = Shader'EnergyTankShaderRed'
	RepSkin  = Shader'EnergyTankShaderRed'
	Mesh     = Mesh'AS_VehiclesFull_M.IonTankMachineGun'

	bAmbientFireSound = False
	Begin Object Class=ProceduralSound Name=GaussFireSound
		BaseSound = Sound'GaussFire'
		PitchModification = -3.0
		PitchVariance     =  6.0
	End Object
	FireSoundClass    = Sound'GaussFireSound'

	AmbientEffectEmitterClass = None
	EffectEmitterClass        = class'GaussFireEffect'
	WeaponFireAttachmentBone  = Object02
	WeaponFireOffset = 72.0
	DualFireOffset   =  8.5
	DrawScale        =  1.2

	DamageType   = class'DamTypeNekomataMinigun'
	DamageRadius = 35.0
	DamageMin    = 29
	DamageMax    = 31
	Spread       = 0.005
	FireInterval = 0.2
	Momentum     = 5000.0

	bInstantRotation   = False
	RotationsPerSecond = 1.0
	FireRecoilAmount   = 1000.0
	bDoOffsetTrace     = True
	PitchDownLimit     = 61000

	AIInfo[0] = (bTrySplash=True)
}