ChatToConsoleCommand.ChatToConsoleCommandHandler

/******************************************************************************
ChatToConsoleCommandHandler

Creation date: 2013-03-21 18:24
Last change: $Id$
Copyright © 2013, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class ChatToConsoleCommandHandler extends BroadcastHandler;


struct TranslationEntry
{
	var config string ChatLine;
	var config string ConsoleCommand;
	var config bool bCaseSensitive;
};

var config array<TranslationEntry> Translate;

var string LastMsg;


function PreBeginPlay()
{
	local BroadcastHandler BH;

	for (BH = Level.Game.BroadcastHandler; BH != None; BH = BH.NextBroadcastHandler) {
		if (BH.Class == Class)
			return; // already registered
	}

	default.NextBroadcastHandlerClass = None; // ensure no left-overs from previous level
	Level.Game.BroadcastHandler.RegisterBroadcastHandler(Self);
	SaveConfig();
}


static event bool AcceptPlayInfoProperty(string PropName)
{
	if (PropName ~= "bPartitionSpectators" || PropName ~= "bMuteSpectators")
		return false; // not our business

	return Super.AcceptPlayInfoProperty(PropName);
}


function bool AcceptBroadcastText(PlayerController Receiver, PlayerReplicationInfo SenderPRI, out string Msg, optional name Type)
{
	local int i;

	if (LastMsg != Msg && Type == 'Say' && SenderPRI != None && PlayerController(SenderPRI.Owner) != None)
	{
		LastMsg = Msg;
		for (i = 0; i < Translate.Length; i++)
		{
			if (Translate[i].bCaseSensitive && Translate[i].ChatLine != Msg)
				continue;

			if (Translate[i].ChatLine ~= Msg)
			{
				//log(SenderPRI.PlayerName $ " - \"" $ Msg $ "\" -> " $ Translate[i].ConsoleCommand, 'Translate');
				PlayerController(SenderPRI.Owner).ConsoleCommand(Translate[i].ConsoleCommand);
				break;
			}
		}
	}
	return Super.AcceptBroadcastText(Receiver, SenderPRI, Msg, Type);
}



//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	Translate(0) = (ConsoleCommand="mutate teams",ChatLine="!teams")
}