OnslaughtSpecialsLiteV2.ACTION_IfNodeOwnedBy

/******************************************************************************
ACTION_IfNodeOwnedBy

Creation date: 2010-08-26 17:51
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class ACTION_IfNodeOwnedBy extends ScriptedAction;


/** Tag of node to test. */
var() name NodeTag;

/** Tag of core to test against. */
var() name CoreTag;

/** Team number to test against. */
var() byte TeamNum;

var ONSPowerCore Node;
var ONSPowerCore Core;


function ProceedToNextAction(ScriptedController C)
{
	C.ActionNum += 1;

	if (Node == None && NodeTag != '') {
		foreach C.AllActors(class'ONSPowerCore', Node, NodeTag) {
			break;
		}
		if (Node == None) {
			log(C.SequenceScript@C.ActionNum@Name@"- No power node for tag '"$NodeTag$"'");
			NodeTag = '';
		}
	}
	if (Core == None && CoreTag != '') {
		foreach C.AllActors(class'ONSPowerCore', Core, CoreTag) {
			break;
		}
		if (Core == None) {
			log(C.SequenceScript@C.ActionNum@Name@"- No power core for tag '"$CoreTag$"'");
			CoreTag = '';
		}
	}

	if (Node == None || TeamNum <= 2 && TeamNum == Node.DefenderTeamIndex || Core != None && Core.DefenderTeamIndex < 2 && Core.DefenderTeamIndex != Node.DefenderTeamIndex)
		ProceedToSectionEnd(C);
}


function bool StartsSection()
{
	return true;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	ActionString = "If node/core is owned"
	TeamNum = 255
}