OnslaughtSpecialsLiteV2.ACTION_IfNodeShielded

/******************************************************************************
Enters the following section only if the specified node is shielded.

Creation date: 2010-08-08 15:20
Last change: $Id$
Copyright (c) 2010, Wormbo
******************************************************************************/

class ACTION_IfNodeShielded extends ScriptedAction;


var() name NodeTag;
var ONSPowerCore Node;


function ProceedToNextAction(ScriptedController C)
{
	C.ActionNum += 1;
	
	if (Node == None && NodeTag != '') {
		foreach C.AllActors(class'ONSPowerCore', Node, NodeTag) {
			break;
		}
		if (Node == None) {
			log(C.SequenceScript@C.ActionNum@Name@"- No power node/core for tag '"$NodeTag$"'");
			NodeTag = '';
		}
	}
	
	if (Node == None || Node.DefenderTeamIndex == 2 || Node.PoweredBy(1 - Node.DefenderTeamIndex))
		ProceedToSectionEnd(C);
}


function bool StartsSection()
{
	return true;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	ActionString = "If node/core is shielded"
}