ServerDecals.DecalReplicationInfo

/******************************************************************************
DecalReplicationInfo

Creation date: 2010-07-15 11:08
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class DecalReplicationInfo extends ReplicationInfo dependson(MapDecals);


//=============================================================================
// Variables
//=============================================================================

/** Replicated projectile properties. */
var struct TRepDecal {
	var Material ProjTexture;
	var vector   Location;
	var vector   Rotation; // replicated as vector for full precision
	
	var Projector.EProjectorBlending MaterialBlendingOp;
	var Projector.EProjectorBlending FrameBufferBlendingOp;
	
	var float DrawScale;
	var byte  FOV;
	var int   MaxTraceDistance;
	var bool  bProjectBSP;
	var bool  bProjectTerrain;
	var bool  bProjectStaticMesh;
	var bool  bProjectParticles;
	var bool  bProjectActor;
	var bool  bClipBSP;
	var bool  bClipStaticMesh;
	var bool  bProjectOnUnlit;
	var bool  bGradient;
	var bool  bProjectOnBackfaces;
	var bool  bProjectOnAlpha;
	var bool  bProjectOnParallelBSP;
	var name  ProjectTag;
} RepDecal;


//=============================================================================
// Replication
//=============================================================================

replication
{
	reliable if (bNetInitial && RepDecal.ProjTexture != None)
		RepDecal;
}


function SetDecal(MapDecals.TDecal Decal)
{
	RepDecal.ProjTexture = Material(DynamicLoadObject(Decal.ProjTexture, class'Material'));
	if (RepDecal.ProjTexture == None) {
		Destroy();
		return;
	}
	AddToPackageMap(Left(Decal.ProjTexture, InStr(Decal.ProjTexture, ".")));
	
	RepDecal.Location              = Decal.Location;
	RepDecal.Rotation              = VectorRotation(Decal.Rotation);
	RepDecal.MaterialBlendingOp    = Decal.MaterialBlendingOp;
	RepDecal.FrameBufferBlendingOp = Decal.FrameBufferBlendingOp;
	RepDecal.DrawScale             = Decal.DrawScale;
	RepDecal.FOV                   = Clamp(Decal.FOV, 0, 180);
	RepDecal.MaxTraceDistance      = Decal.MaxTraceDistance;
	RepDecal.bProjectBSP           = Decal.bProjectBSP;
	RepDecal.bProjectTerrain       = Decal.bProjectTerrain;
	RepDecal.bProjectStaticMesh    = Decal.bProjectStaticMesh;
	RepDecal.bProjectParticles     = Decal.bProjectParticles;
	RepDecal.bProjectActor         = Decal.bProjectActor;
	RepDecal.bClipBSP              = Decal.bClipBSP;
	RepDecal.bClipStaticMesh       = Decal.bClipStaticMesh;
	RepDecal.bProjectOnUnlit       = Decal.bProjectOnUnlit;
	RepDecal.bGradient             = Decal.bGradient;
	RepDecal.bProjectOnBackfaces   = Decal.bProjectOnBackfaces;
	RepDecal.bProjectOnAlpha       = Decal.bProjectOnAlpha;
	RepDecal.bProjectOnParallelBSP = Decal.bProjectOnParallelBSP;
	RepDecal.ProjectTag            = Decal.ProjectTag;
	
	if (Level.NetMode != NM_DedicatedServer)
		SpawnDecal();
}

simulated function PostNetReceive()
{
	if (RepDecal.ProjTexture == None)
		return;
	
	SpawnDecal();
	bNetNotify = False;
}

simulated function SpawnDecal()
{
	Spawn(class'ConfiguredDecal', Self, '', RepDecal.Location, RotationVector(RepDecal.Rotation));
}


//=============================================================================
// Utility functions
//=============================================================================

static final function rotator RotationVector(vector V)
{
	local rotator R;
	
	R.Pitch = V.X;
	R.Yaw   = V.Y;
	R.Roll  = V.Z;
	
	return R;
}

static final function vector VectorRotation(rotator R)
{
	local vector V;
	
	R = Normalize(R);
	V.X = R.Pitch;
	V.Y = R.Yaw;
	V.Z = R.Roll;
	
	return V;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	bNetNotify = True
}