SpawnWithLockerWeapons.SpawnWithLockerWeapons

/******************************************************************************
SpawnWithLockerWeapons

Creation date: 2009-02-07 13:19
Last change: $Id$
Copyright (c) 2009, Wormbo
******************************************************************************/

class SpawnWithLockerWeapons extends Mutator;


struct TBestLocker {
	var Actor Start;
	var WeaponLocker Locker;
};

var bool bInitialized;
var array<TBestLocker> BestLockers;
var array<WeaponLocker> AllLockers;
var array<UnrealPawn> SpawnedPlayers;

function Initialize()
{
	local int i;
	local WeaponLocker Locker;
	
	bInitialized = True;
	
	// find all lockers for faster access
	foreach AllActors(class'WeaponLocker', Locker) {
		if (Locker.IsInState('LockerPickup'))
			AllLockers[i++] = Locker;
	}
	AllLockers.Length = i; // just making sure
}

function ModifyPlayer(Pawn Other)
{
	local int i;
	local WeaponLocker BestLocker;
	local Weapon Copy;
	
	if (!bInitialized)
		Initialize();
	
	Super.ModifyPlayer(Other);
	
	if (UnrealPawn(Other) != None) {
		// check if we processed this player already
		for (i = SpawnedPlayers.Length - 1; i >= 0; --i) {
			if (SpawnedPlayers[i] == None || SpawnedPlayers[i].Health <= 0)
				SpawnedPlayers.Remove(i, 1);
			else if (SpawnedPlayers[i] == Other)
				return;
		}
		SpawnedPlayers[SpawnedPlayers.Length] = UnrealPawn(Other);
		
		BestLocker = GetBestLocker(Other.LastStartSpot);
		if (BestLocker != None) {
			for (i = 0; i < BestLocker.Weapons.Length; ++i) {
				BestLocker.InventoryType = BestLocker.Weapons[i].WeaponClass;
				Copy =  Weapon(Other.FindInventoryType(BestLocker.Weapons[i].WeaponClass));
				if (Copy != None) {
					Copy.FillToInitialAmmo();
				}
				else if (Level.Game.PickupQuery(Other, BestLocker)) {
					Copy = Weapon(BestLocker.SpawnCopy(Other));
					if (Copy != None) {
						Copy.PickupFunction(Other);
						if (BestLocker.Weapons[i].ExtraAmmo > 0)
							Copy.AddAmmo(BestLocker.Weapons[i].ExtraAmmo, 0);
					}
				}
			}
		}
	}
}


function WeaponLocker GetBestLocker(Actor Start)
{
	local int i;
	local WeaponLocker BestLocker;
	local float Dist, BestDist;
	
	if (AllLockers.Length == 0 || Start == None)
		return None; // no lockers on map
	
	// check if best locker already known
	for (i = 0; i < BestLockers.Length; ++i) {
		if (BestLockers[i].Start == Start)
			return BestLockers[i].Locker; // previously known best locker
	}
	
	// look for closest locker
	for (i = 0; i < AllLockers.Length; ++i) {
		if (AllLockers[i] != None && !AllLockers[i].IsInState('Disabled')) {
			Dist = VSize(Start.Location - AllLockers[i].Location);
			if (BestLocker == None || BestDist > Dist) {
				BestLocker = AllLockers[i];
				BestDist = Dist;
			}
		}
	}
	
	// cache result
	BestLockers.Insert(0, 1);
	BestLockers[0].Locker = BestLocker;
	BestLockers[0].Start = Start;
	
	return BestLocker;
}



//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	FriendlyName = "Spawn with locker weapons"
	Description  = "Spawning players are automatically equiped with all weapons from the nearest weapon locker."
}