StormCasterV2.LightningEmitterAir

/******************************************************************************
LightningEmitterAir

Creation date: 2013-09-09 17:04
Last change: $Id$
Copyright © 2013, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class LightningEmitterAir extends Emitter;


//=============================================================================
// Variables
//=============================================================================

var vector LightningStart;


//=============================================================================
// Replication
//=============================================================================

replication
{
	reliable if (bNetInitial)
		LightningStart;
}


simulated function PostNetBeginPlay()
{
	if (Role < ROLE_Authority)
		UpdateLightningStart();
}


function SetLightningStart(vector NewLightningStart)
{
	LightningStart = NewLightningStart;
	UpdateLightningStart();
}


simulated function UpdateLightningStart()
{
	local vector Offset;
	local BeamEmitter BE;

	Offset = LightningStart - Location;
	BE = BeamEmitter(Emitters[1]);
	BE.BeamEndPoints[0].Offset.X.Min = Offset.X;
	BE.BeamEndPoints[0].Offset.X.Max = Offset.X;
	BE.BeamEndPoints[0].Offset.Y.Min = Offset.Y;
	BE.BeamEndPoints[0].Offset.Y.Max = Offset.Y;
	BE.BeamEndPoints[0].Offset.Z.Min = Offset.Z;
	BE.BeamEndPoints[0].Offset.Z.Max = Offset.Z;
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	bNoDelete       = False
	bNetTemporary   = True
	RemoteRole      = ROLE_SimulatedProxy
	LifeSpan        = 1.0
	AutoDestroy     = True
	bNotOnDedServer = False
	bAlwaysRelevant = True

	Begin Object Class=BeamEmitter Name=LightningBranches
		BeamEndPoints(0)=(offset=(X=(Min=-500.0,Max=500.0),Y=(Min=-500.0,Max=500.0),Z=(Min=-500.0,Max=500.0)))
		DetermineEndPointBy=PTEP_Offset
		RotatingSheets=2
		LowFrequencyNoiseRange=(X=(Min=-50.0,Max=50.0),Y=(Min=-50.0,Max=50.0),Z=(Min=-50.0,Max=50.0))
		HighFrequencyNoiseRange=(X=(Min=-10.0,Max=10.0),Y=(Min=-10.0,Max=10.0),Z=(Min=10.0,Max=10.0))
		HighFrequencyPoints=5
		NoiseDeterminesEndPoint=True
		UseColorScale=True
		ColorScale(0)=(Color=(B=255,G=255,R=255))
		ColorScale(1)=(RelativeTime=0.1,Color=(B=255,G=255,R=255))
		ColorScale(2)=(RelativeTime=0.3,Color=(B=64,G=64,R=64))
		ColorScale(3)=(RelativeTime=0.4,Color=(B=255,G=255,R=255))
		ColorScale(4)=(RelativeTime=1.0)
		ColorMultiplierRange=(X=(Min=0.7,Max=0.8),Y=(Min=0.8,Max=0.9))
		MaxParticles=50
		RespawnDeadParticles=False
		StartSizeRange=(X=(Min=20.0,Max=25.0),Y=(Min=20.0,Max=25.0),Z=(Min=20.0,Max=25.0))
		AutomaticInitialSpawning=False
		InitialParticlesPerSecond=0.0
		DrawStyle=PTDS_Brighten
		Texture=Texture'EpicParticles.Beams.HotBolt04aw'
		SecondsBeforeInactive=0.000000
		LifetimeRange=(Min=0.5,Max=0.5)
	End Object
	Emitters(0)=BeamEmitter'LightningBranches'

	Begin Object Class=BeamEmitter Name=MainLightning
		BeamEndPoints(0)=(offset=(X=(Min=-1000.0,Max=1000.0),Y=(Min=-1000.0,Max=1000.0),Z=(Min=5000.0,Max=5000.0)))
		DetermineEndPointBy=PTEP_Offset
		BeamTextureUScale=3.0
		RotatingSheets=2
		LowFrequencyNoiseRange=(X=(Min=-200.0,Max=200.0),Y=(Min=-200.0,Max=200.0),Z=(Min=-200.0,Max=200.0))
		LowFrequencyPoints=4
		HighFrequencyNoiseRange=(X=(Min=-40.0,Max=40.0),Y=(Min=-40.0,Max=40.0),Y=(Min=-40.0,Max=40.0))
		HighFrequencyPoints=10
		UseBranching=True
		BranchProbability=(Min=0.2,Max=0.2)
		BranchHFPointsRange=(Min=1.0,Max=9.0)
		BranchEmitter=0
		BranchSpawnAmountRange=(Min=1.0,Max=1.0)
		LinkupLifetime=True
		//NoiseDeterminesEndPoint=True
		UseColorScale=True
		ColorScale(0)=(Color=(B=255,G=255,R=255))
		ColorScale(1)=(RelativeTime=0.1,Color=(B=255,G=255,R=255))
		ColorScale(2)=(RelativeTime=0.3,Color=(B=64,G=64,R=64))
		ColorScale(3)=(RelativeTime=0.4,Color=(B=255,G=255,R=255))
		ColorScale(4)=(RelativeTime=1.0)
		ColorMultiplierRange=(X=(Min=0.7,Max=0.8),Y=(Min=0.8,Max=0.9))
		MaxParticles=1
		RespawnDeadParticles=False
		StartSizeRange=(X=(Min=40.0,Max=40.0),Y=(Min=40.0,Max=40.0),Z=(Min=40.0,Max=40.0))
		Sounds(0)=(Sound=Sound'StormThunder1',Radius=(Min=2000.0,Max=3000.0),Pitch=(Min=0.8,Max=1.2),Weight=1,Volume=(Min=1.0,Max=1.8),Probability=(Min=1.0,Max=1.0))
		Sounds(1)=(Sound=Sound'StormThunder2',Radius=(Min=2000.0,Max=3000.0),Pitch=(Min=0.8,Max=1.2),Weight=1,Volume=(Min=1.0,Max=1.6),Probability=(Min=1.0,Max=1.0))
		Sounds(2)=(Sound=Sound'StormThunder3',Radius=(Min=2000.0,Max=3000.0),Pitch=(Min=0.8,Max=1.2),Weight=1,Volume=(Min=1.0,Max=1.6),Probability=(Min=1.0,Max=1.0))
		Sounds(3)=(Sound=Sound'StormThunder4',Radius=(Min=2000.0,Max=3000.0),Pitch=(Min=0.8,Max=1.2),Weight=1,Volume=(Min=1.0,Max=1.8),Probability=(Min=1.0,Max=1.0))
		SpawningSound=PTSC_Random
		SpawningSoundIndex=(Max=4.000000)
		SpawningSoundProbability=(Min=1.0,Max=1.0)
		InitialParticlesPerSecond=1000.0
		AutomaticInitialSpawning=False
		DrawStyle=PTDS_Brighten
		Texture=Texture'EpicParticles.Beams.HotBolt03aw'
		SecondsBeforeInactive=0.000000
		LifetimeRange=(Min=0.5,Max=0.5)
	End Object
	Emitters(1)=BeamEmitter'MainLightning'
}