UTPlusStandaloneHitSounds.MutUTPlusHitSounds

/******************************************************************************
MutUTPlusHitSounds

Creation date: 2010-12-22 17:48
Last change: $Id$
Copyright © 2010, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class MutUTPlusHitSounds extends Mutator config;


//=============================================================================
// Configuration
//=============================================================================

var config bool bAllowVariableHitSounds;
var config bool bLineOfSightHitSounds;
var config bool bObjectiveHitSounds;


//=============================================================================
// Localization
//=============================================================================

var localized string lblAllowVariableHitSounds;
var localized string lblLineOfSightHitSounds;
var localized string lblObjectiveHitSounds;
var localized string descAllowVariableHitSounds;
var localized string descLineOfSightHitSounds;
var localized string descObjectiveHitSounds;


function PreBeginPlay()
{
	local UTPlusHitSounds HitSounds;

	// check for server actor first
	foreach AllActors(class'UTPlusHitSounds', HitSounds) {
		return;
	}
	Spawn(class'UTPlusHitSounds');
}


/**
Add the configuration options to the PlayInfo.
*/
static function FillPlayInfo(PlayInfo PlayInfo)
{
	Super.FillPlayInfo(PlayInfo);

	PlayInfo.AddSetting(default.FriendlyName, "bAllowVariableHitSounds", default.lblAllowVariableHitSounds, 0, 0, "Check");
	PlayInfo.AddSetting(default.FriendlyName, "bLineOfSightHitSounds",   default.lblLineOfSightHitSounds,   0, 0, "Check");
	PlayInfo.AddSetting(default.FriendlyName, "bObjectiveHitSounds",     default.lblObjectiveHitSounds,     0, 0, "Check");
}


/**
Returns a description for the specified configuration option.
*/
static event string GetDescriptionText(string PropName)
{
	switch (PropName) {
		case "bAllowVariableHitSounds": return default.descAllowVariableHitSounds;
		case "bLineOfSightHitSounds":   return default.descLineOfSightHitSounds;
		case "bObjectiveHitSounds":     return default.descObjectiveHitSounds;
	}

	return Super.GetDescriptionText(PropName);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	FriendlyName  = "UTPlus 2 HitSounds (Standalone)"
	GroupName     = "HitSounds"
	Description   = "Activates UTPlus hit sounds."

	bAllowVariableHitSounds = True
	bLineOfSightHitSounds   = True
	bObjectiveHitSounds     = True

	lblAllowVariableHitSounds = "Allow variable hit sounds"
	lblLineOfSightHitSounds   = "Use line-of-sight hit sounds"
	lblObjectiveHitSounds     = "Objective hit sounds"

	descAllowVariableHitSounds  = "Allow variable hit sounds pitch based on damage."
	descLineOfSightHitSounds    = "Hit sounds will only play if the attacker has a line of sight to the victim."
	descObjectiveHitSounds      = "Plays hit sounds for damaging destroyable objectives in assault and power nodes/cores in Onslaught."
}