WormbotHandlerUTComp.WIR_ModHandler_UTComp

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Handler for UTComp. Lot's of GetPropertyText() here so I don't depend on any
specific version of that mess some people call a mutator.
******************************************************************************/


class WIR_ModHandler_UTComp extends WIR_ModHandler;


//=============================================================================
// Localization
//=============================================================================

var localized string MsgVoteStarted;
var localized string StringWarmup;
var localized string StringPrefixWarmupTime;
var localized string StringSuffixWarmupTime;


//=============================================================================
// Variables
//=============================================================================

var ReplicationInfo UTCompWarmup;


//== GetRemainingTime =========================================================
/**
Returns the time remaining in the match or the time elapsed if there's no time limit.
*/
//============================================================================= 

function string GetRemainingTime()
{
  local string Time;
  local int Seconds;
  
  Time = Super.GetRemainingTime();
  if ( Time != "" )
    return Time;
  
  if ( UTCompWarmup == None ) {
    foreach DynamicActors(class'ReplicationInfo', UTCompWarmup)
      if ( UTCompWarmup.IsA('UTComp_Warmup') )
        break;
    if ( UTCompWarmup != None && !UTCompWarmup.IsA('UTComp_Warmup') )
      UTCompWarmup = None;
  }
  if ( UTCompWarmup != None && bool(UTCompWarmup.GetPropertyText("bInWarmup")) ) {
    if ( bool(UTCompWarmup.GetPropertyText("bInFinalCountdown")) )
      Seconds = int(UTCompWarmup.GetPropertyText("iFinalCountDown"));
    else if ( !bool(UTCompWarmup.GetPropertyText("bTimeUnlimitedWarmup")) )
      Seconds = int(UTCompWarmup.GetPropertyText("iWarmupTimeRemaining"));
    else
      return StringWarmup;
    
    return StringPrefixWarmupTime $ class'WIR_Util'.static.FormatTime(Seconds, true, true) $ StringSuffixWarmupTime;
  }
  
  return "";
}


//== HandleLocalizedMessage ===================================================
/**
Return True if the message should not be reported through the default event.
*/
//=============================================================================

function bool HandleLocalizedMessage(class<LocalMessage> Message, int Switch, PlayerReplicationInfo RelatedPRI_1, PlayerReplicationInfo RelatedPRI_2, Object OptionalObject)
{
  if ( Message.Name == 'UTComp_Vote_Started' ) {
    if ( MyMutator != None && MyMutator.ReportConnection != None )
      MyMutator.ReportConnection.SendMessage(Repl(MsgVoteStarted, "%r", MyMutator.MyGameHandler.GetRemainingTime(), True));
    return true;
  }
  if ( Super.HandleLocalizedMessage(Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject) || Message.Name == 'UTComp_Warmup_CountDown' )
    return true;
  
  return false;
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
  StringWarmup            = "Warmup"
  StringPrefixWarmupTime  = "W-"
  MsgVoteStarted          = "[%r] - [^B]A Vote Was Started![^B]"
}