WVDraco.DracoRocketPack

/******************************************************************************
DracoRocketPack

Creation date: 2013-04-28 09:23
Last change: $Id$
Copyright © 2013, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class DracoRocketPack extends ONSWeapon;


//=============================================================================
// Imports
//=============================================================================

#exec audio import file=Sounds\NapalmRocketFire.wav

var bool bTurnedOff;

simulated function Tick(float DeltaTime)
{
	if (bTurnedOff)
		return;

	if (Instigator != None && Instigator.PlayerReplicationInfo != None)
	{
		bForceCenterAim = False;
	}
	else if (!bActive && CurrentAim != rot(0,0,0))
	{
		bForceCenterAim = True;
		bActive = True;
	}
	else if (bActive && CurrentAim == rot(0,0,0))
	{
		bActive = False;
	}
}

function bool CanAttack(Actor Other)
{
	return Super.CanAttack(Other) && CheckAngle(Normal(Other.Location - WeaponFireLocation));
}

simulated function bool CheckAngle(vector Dir)
{
	local vector WeaponDir;
	
	WeaponDir = Normal(Owner.Location - Location) << Owner.Rotation;
	Dir = Dir << Owner.Rotation;
	
	if (Dir.Y > 0 ^^ WeaponDir.Y > 0)
		return true;
	
	if (Dir.X > 0)
		return Dir.X > 0.7 || Dir.Z < -0.8 || Dir.Z > 0.1;
	else
		return Dir.X < -0.5 || Dir.Z < -0.7 || Dir.Z > 0.0;
}

function Projectile SpawnProjectile(class<Projectile> ProjClass, bool bAltFire)
{
	if (!CheckAngle(vector(WeaponFireRotation)))
	{
		if (Bot(Instigator.Controller) != None)
			DracoRocketPackPawn(Instigator).ConsiderSwitchingSides();
		else if (PlayerController(Instigator.Controller) != None)
			PlayerController(Instigator.Controller).ClientPlaySound(Sound'Denied1');
		return None;
	}
	return Super.SpawnProjectile(ProjClass, bAltFire);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	Mesh      = Mesh'ONSFullAnimations.MASRocketPack'
	DrawScale = 0.4
	Skins(0)  = Shader'DracoRocketPackShader'

	YawBone            = RocketPivot
	YawStartConstraint =     0
	YawEndConstraint   = 65535
	PitchBone          = RocketPacks
	PitchUpLimit       = 12000
	PitchDownLimit     = 50000
	bAimable           = True

	FireSoundClass  = Sound'NapalmRocketFire'
	FireForce       = "RocketLauncherFire"
	ProjectileClass = class'DracoNapalmRocket'
	FireInterval    = 0.7
	Spread          = 0.015

	WeaponFireAttachmentBone  = RocketPackFirePoint
	WeaponFireOffset          =  0.0
	DualFireOffset            = 32.0
	bDualIndependantTargeting = True

	AIInfo(0) = (bLeadTarget=true,bTrySplash=true,WarnTargetPct=1.0,RefireRate=0.5)
}