WVPersesMAS.PersesFragChunk

/**
WVPersesMAS.PersesFragChunk

Creation date: 2013-12-12 12:52
Last change: $Id$
Copyright (c) 2013, Wormbo
*/

class PersesFragChunk extends PersesProjectileBase;


//=============================================================================
// Imports
//=============================================================================

#exec audio import file=Sounds\FragBounce1.wav
#exec audio import file=Sounds\FragBounce2.wav


//=============================================================================
// Properties
//=============================================================================

var array<Sound> ImpactSounds;


//=============================================================================
// Variables
//=============================================================================

var byte RemainingBounces;


replication
{
	reliable if (bNetInitial)
		RemainingBounces;
}


simulated function ProcessContact(Actor Other, vector HitLocation, vector HitNormal)
{
	ExplosionSound = ImpactSounds[Rand(ImpactSounds.Length)];
	
	if (Other != None && (Other.bStatic || Other.bWorldGeometry) && RemainingBounces != 0)
	{
		Bounce(HitLocation, HitNormal);
	}
	else
	{
		Damage *= VSize(Velocity) / MaxSpeed;
		Explode(HitLocation, HitNormal);
	}
}

simulated function Bounce(vector HitLocation, vector HitNormal)
{
	RemainingBounces--;
	
	if (Role == ROLE_Authority)
		MakeNoise(0.5);

	if (LastTouched != None)
	{
		LastTouched.TakeDamage(Damage * VSize(Velocity) / MaxSpeed, Instigator, HitLocation, Normal(Velocity) * MomentumTransfer, MyDamageType);
	}
	else if (HurtWall != None)
	{
		HurtWall.TakeDamage(Damage * VSize(Velocity) / MaxSpeed, Instigator, HitLocation, Normal(Velocity) * MomentumTransfer, MyDamageType);
	}
	SpawnExplosionEffects(HitLocation, HitNormal);
	
	Velocity = MirrorVectorByNormal(Velocity, HitNormal) * 0.85;
	
	if (ProjEffects != None)
	{
		ProjEffects.SetBase(None);
		ProjEffects.SetLocation(HitLocation);
	}
	SpawnFlightEffects(); // create a new trail so the old one ends at the impact location
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	Damage           =    20.0
	DamageRadius     =     0.0
	MomentumTransfer = 10000.0
	MyDamageType     = class'DamTypePersesFragChunk'
	RemainingBounces = 3
	bBlockedByInstigator = True
	
	Mass     =    1.0
	LifeSpan =    1.0
	Speed    = 6000.0
	MaxSpeed = 6000.0
	Physics  = PHYS_Falling
	bIgnoreTerminalVelocity = True
	
	FlightParticleSystem = class'PersesFragChunkFlightEffects'
	ExplosionParticleSystem = class'PersesFragImpactSparks'
	ImpactSounds = (Sound'FragBounce1',Sound'FragBounce2')
	ExplosionDecal = class'BulletDecal'
	MaxEffectDistance    = 5000.0
	
}