PlayerRedirector.MutPlayerRedirector

/******************************************************************************
MutPlayerRedirector

Creation date: 2011-09-20 18:32
Last change: $Id$
Copyright © 2011, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class MutPlayerRedirector extends Mutator config;


var() config string RedirectionURL;

var array<PlayerController> NewPlayers;


function bool CheckReplacement(Actor Other, out byte bSuperRelevant)
{
	if (PlayerController(Other) != None)
		NewPlayers[NewPlayers.Length] = PlayerController(Other);

	return true;
}

function Tick(float DeltaTime)
{
	if (NewPlayers.Length > 0 && RedirectionURL != "") {
		if (NewPlayers[0] != None && NetConnection(NewPlayers[0].Player) != None)
			NewPlayers[0].ClientTravel(RedirectionURL, TRAVEL_Absolute, False);

		NewPlayers.Remove(0, 1);
	}
}


static function FillPlayInfo(PlayInfo PlayInfo)
{
	Super.FillPlayInfo(PlayInfo);
	PlayInfo.AddSetting(default.ServerGroup, "RedirectionURL", "Player Redirection URL", 0, 0, "Text", "100");
}

static event string GetDescriptionText(string PropName)
{
	if (PropName == "RedirectionURL")
		return "URL to send connecting players to.";

	return Super.GetDescriptionText(PropName);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	FriendlyName = "Player Redirector"
	Description  = "Sends players to a different server right after they connected."
}