WormbotHandlerJailbreak.WIR_GameHandler_Jailbreak

/******************************************************************************
Copyright (c) 2005-2007 by Wormbo <wormbo@online.de>
$Id$

Handler for Jailbreak.
******************************************************************************/


class WIR_GameHandler_Jailbreak extends WIR_GameHandler;


//=============================================================================
// Localization
//=============================================================================

var localized string MsgTeamCaptured;
var localized string MsgTeamCapturedBoth;
var localized string MsgTeamReleased;
var localized string MsgArenaMatchStarted;
var localized string MsgArenaMatchCanceled;
var localized string MsgArenaMatchEnded;
var localized string MsgArenaMatchEndedTied;

var localized string MsgLlamaStart;
var localized string MsgLlamaKilled;
var localized string MsgLlamaSuicided;
var localized string MsgLlamaDisconnect;

var localized string MsgOvertimeLockdown;

var localized string StringPrefixLlama;


//=============================================================================
// Variables
//=============================================================================

var JBAddonLlama LlamaAddon;


//== PostBeginPlay ============================================================
/**
Initialize the handler.
*/
//=============================================================================

event PostBeginPlay()
{
	Super.PostBeginPlay();

	foreach DynamicActors(class'JBAddonLlama', LlamaAddon) {
		log("Llama Hunt Add-On is available", Name);
		break;
	}
	Spawn(class'WIR_JBGameRules', Owner);
}


//== HandleKill ===============================================================
/**
Prevent suicide messages during executions.
*/
//=============================================================================

function bool HandleKill(out Controller Killer, out Controller Killed, out class<DamageType> DamageType, out string MsgSuffix)
{
	if ( Super.HandleKill(Killer, Killed, DamageType, MsgSuffix) || Level.Game.IsInState('Executing') )
		return true;

	return false;
}


//== HandleLocalizedMessage ===================================================
/**
Return True if the message should not be reported through the default event.
*/
//=============================================================================

function bool HandleLocalizedMessage(class<LocalMessage> Message, int Switch, PlayerReplicationInfo RelatedPRI_1, PlayerReplicationInfo RelatedPRI_2, Object OptionalObject)
{
	local string Msg;

	if ( MyMutator != None && MyMutator.ReportConnection != None ) {
		if ( class<JBLocalMessage>(Message) != None ) {
			switch (Switch) {
				case 100: // team captured
					Msg = Repl(MsgTeamCaptured, "%t", class'WIR_Util'.static.FormatTeamName(TeamInfo(OptionalObject), False), True);
					MyMutator.bReportScoreboard = True;
					break;

				case 200: // team released by PRI1
					Msg = Repl(MsgTeamReleased, "%t", class'WIR_Util'.static.FormatTeamName(TeamInfo(OptionalObject), False), True);
					Msg = Repl(Msg, "%p", FormatPlayerName(RelatedPRI_1, True), True);
					break;

				case 300: // both captured
					Msg = MsgTeamCapturedBoth;
					break;

				case 400: // arena match between PRI1 & 2 in OptObj started
					Msg = MsgArenaMatchStarted;
					Msg = Repl(Msg, "%p1", FormatPlayerName(RelatedPRI_1, True), True);
					Msg = Repl(Msg, "%p2", FormatPlayerName(RelatedPRI_2, True), True);
					break;

				case 410: // arena match between PRI1 & 2 in OptObj canceled
					Msg = MsgArenaMatchCanceled;
					Msg = Repl(Msg, "%p1", FormatPlayerName(RelatedPRI_1, True), True);
					Msg = Repl(Msg, "%p2", FormatPlayerName(RelatedPRI_2, True), True);
					break;

				case 420: // arena match between PRI1 & 2 in OptObj tied
					Msg = MsgArenaMatchEndedTied;
					Msg = Repl(Msg, "%p1", FormatPlayerName(RelatedPRI_1, True), True);
					Msg = Repl(Msg, "%p2", FormatPlayerName(RelatedPRI_2, True), True);
					break;

				case 430: // PRI1 wins arena match vs PRI2 in OptObj
					Msg = MsgArenaMatchEnded;
					Msg = Repl(Msg, "%p", FormatPlayerName(RelatedPRI_1, True), True);
					Msg = Repl(Msg, "%o", FormatPlayerName(RelatedPRI_2, True), True);
					break;

				case 900: // game started
					break;

				case 910: // overtime
					Msg = MsgGameOvertime;
					break;

				case 920: // game ended (winner)
					break;
			}

			if ( Msg != "" )
				MyMutator.ReportConnection.SendMessage(Repl(Msg, "%r", GetRemainingTime(), True));

			return true;
		}

		if ( Message.Name == 'JBLlamaMessage' ) {
			switch (Switch) {
				case 1: // player became llama
					Msg = MsgLlamaStart;
					break;

				case 2: // llama was killed by a player
					Msg = Repl(MsgLlamaKilled, "%p", FormatPlayerName(RelatedPRI_2, True), True);
					break;

				case 3: // llama suicided
					Msg = MsgLlamaSuicided;
					break;

				case 4: // llama disconnected (not used here)
					break;
			}

			if ( Msg != "" ) {
				Msg = Repl(Msg, "%l", FormatPlayerName(RelatedPRI_1), True);
				Msg = Repl(Msg, "%r", GetRemainingTime(), True);
				MyMutator.ReportConnection.SendMessage(Msg);
			}
			return true;
		}

		if ( Message.Name == 'JBLocalMessageOvertimeLockdown' ) {
			MyMutator.ReportConnection.SendMessage(Repl(Msg, "%r", GetRemainingTime(), True));
			return true;
		}
	}
	return Super.HandleLocalizedMessage(Message, Switch, RelatedPRI_1, RelatedPRI_2, OptionalObject);
}


//== HandleEndGame ============================================================
/**
Return True if the handler wants to override the mutator's default behavior.
*/
//=============================================================================

function bool HandleEndGame(out string Reason)
{
	local string Msg;

	if ( !Super.HandleEndGame(Reason) ) {
		// handle sending the "game ended" message without displaying the scoreboard the scores
		Msg = Repl(MyMutator.MsgGameEnded, "%r", GetRemainingTime(), True);
		if ( Reason != "" )
			Msg $= Repl(MyMutator.StringMsgSuffix, "%m", Reason, True);
		MyMutator.ReportConnection.SendMessage(Msg, True);
	}
	return true;
}


//== FormatPlayerName =========================================================
/**
Returns a formatted player name for IRC.
*/
//=============================================================================

function string FormatPlayerName(Actor Player, optional bool bOnlyName, optional string StringScoreTemplate, optional out string CustomPrefix)
{
	local PlayerReplicationInfo PRI;
	local Controller C;
	local Pawn P;

	if ( LlamaAddon != None ) {
		class'WIR_Util'.static.GetPlayerActors(Player, C, P, PRI);

		if ( PRI != None && !PRI.bOnlySpectator && (PRI.bOutOfLives || P != None) && LlamaAddon.IsLlama(C) )
			CustomPrefix $= StringPrefixLlama;
	}
	return Super.FormatPlayerName(Player, bOnlyName, StringScoreTemplate, CustomPrefix);
}


//== AddRow ==================================================================
/**
Adds data in a row on the left or right side of the scoreboard table.
*/
//=============================================================================

function AddRow(out array<WIR_Util.TAlignedTable> Table, int row, PlayerReplicationInfo PRI, bool bRightSide)
{
	local int col, coloffset;
	local JBTagPlayer Player;

	Player = class'JBTagPlayer'.static.FindFor(PRI);

	if ( bRightSide )
		coloffset = (Table.Length + 1) / 2;

	if ( Table[col+coloffset].Rows.Length <= row )
		Table[col+coloffset].Rows.Length = row + 1;
	Table[col+coloffset].Rows[row].Content = Repl(FormatPlayerName(PRI, True), "[^B]", "", True); // strip code for bold
	++col;

	if ( Table[col+coloffset].Rows.Length <= row )
		Table[col+coloffset].Rows.Length = row + 1;
	Table[col+coloffset].Rows[row].Content = string(int(PRI.Score));
	++col;

	if ( Table[col+coloffset].Rows.Length <= row )
		Table[col+coloffset].Rows.Length = row + 1;
	Table[col+coloffset].Rows[row].Content = string(Player.ScorePartialAttack);
	++col;

	if ( Table[col+coloffset].Rows.Length <= row )
		Table[col+coloffset].Rows.Length = row + 1;
	Table[col+coloffset].Rows[row].Content = string(Player.ScorePartialDefense);
	++col;

	if ( Table[col+coloffset].Rows.Length <= row )
		Table[col+coloffset].Rows.Length = row + 1;
	Table[col+coloffset].Rows[row].Content = string(Player.ScorePartialRelease);
	++col;
}


//=============================================================================
// Default properties
//=============================================================================

defaultproperties
{
	MsgTeamCaptured         = "[^B][%r][^B] - %t [^B]was captured[^B]"
	MsgTeamCapturedBoth     = "[^B][%r] - Both teams captured - No Score.[^B]"
	MsgTeamReleased         = "[%r] - %t [^B]was released[^B] by %p[^O]"
	MsgArenaMatchStarted    = "[%r] - %p1[^O] and %p2[^O] fight for their freedom in the arena"
	MsgArenaMatchCanceled   = "[%r] - Arena match between %p1[^O] and %p2[^O] was canceled"
	MsgArenaMatchEnded      = "[%r] - %p[^O] has won the arena match - %o[^O] goes back to jail"
	MsgArenaMatchEndedTied  = "[%r] - Arena match between %p1[^O] and %p2[^O] ended with a tie"

	MsgLlamaStart       = "[%r] - The Hunt on %l[^O] has started"
	MsgLlamaKilled      = "[%r] - %l[^O] was caught by %p[^O]"
	MsgLlamaSuicided    = "[%r] - %l[^O] was busted!"

	MsgOvertimeLockdown = "[^B][%r] Overtime Lockdown - Release switches disabled![^B]"

	StringPrefixLlama = "Llama "

	StringTableHeader(0)  = "[^U]Name"
	StringTableHeader(1)  = "Score"
	StringTableHeader(2)  = "Attk."
	StringTableHeader(3)  = "Def."
	StringTableHeader(4)  = "Rel.[^O]"
	StringTableHeader(5)  = " "
	StringTableHeader(6)  = "[^U]Name"
	StringTableHeader(7)  = "Score"
	StringTableHeader(8)  = "Attk."
	StringTableHeader(9)  = "Def."
	StringTableHeader(10) = "Rel.[^O]"

	ColumnAlign(0)  = TXTA_Left
	ColumnAlign(1)  = TXTA_Right
	ColumnAlign(2)  = TXTA_Right
	ColumnAlign(3)  = TXTA_Right
	ColumnAlign(4)  = TXTA_Right
	ColumnAlign(5)  = TXTA_Center
	ColumnAlign(6)  = TXTA_Left
	ColumnAlign(7)  = TXTA_Right
	ColumnAlign(8)  = TXTA_Right
	ColumnAlign(9)  = TXTA_Right
	ColumnAlign(10) = TXTA_Right

	HandlerGroup = "Wormbot (Jailbreak)"
}