WVHoverTankV3.PoltergeistTank

/******************************************************************************
PoltergeistTank

Creation date: 2012-08-14 13:34
Last change: $Id$
Copyright © 2012, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class PoltergeistTank extends HoverTank;


//=============================================================================
// Imports
//=============================================================================

#exec obj load file=EnergyTankMesh.ukx package=WVHoverTankV2.Poltergeist
#exec obj load file=EnergyTankSkins.utx package=WVHoverTankV2.Skins

#exec texture import file=Textures\PoltergeistIcon.dds group=HUD alpha=1 lodset=5


function bool NeedToTurn(vector TargetLocation)
{
	if (VSize(TargetLocation - Location) < 1500 && Normal(TargetLocation - Location) dot Normal(vector(Weapons[ActiveWeapon].CurrentAim) >> Weapons[ActiveWeapon].Rotation) > 0.5)
		return false; // can fire a shockwave, so should be able to hit as long as not too far off

	return Super.NeedToTurn(TargetLocation);
}

function ShouldTargetMissile(Projectile P)
{
	local AIController C;
	local vector PredictedLocation;
	local float PredictedDist;

	if (ActiveWeapon >= Weapons.Length)
		return;

	C = AIController(Controller);
	PredictedLocation = P.Location + P.Velocity * (0.5 + Weapons[ActiveWeapon].FireCountDown);
	if (C != None && C.Skill >= 3.0 && (C.Enemy == None || !C.LineOfSightTo(C.Enemy) || Normal(C.Enemy.Location - Location) dot Normal(PredictedLocation - Location) > 0.5)) {
		// where will the projectile be at the earliest point we could fire a shockwave?
		PredictedDist = VSize(P.Location - Location) - VSize(P.Velocity) * (0.5 + Weapons[ActiveWeapon].FireCountDown);
		if (PredictedDist > 200 && PredictedDist < 1500) {
			ShootMissile(P);
		}
	}
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	DriverWeapons[0] = (WeaponClass=Class'PoltergeistCannon',WeaponBone=MainCannonAttach)

	MinVehicleDistance = -100.0 // nothing wrong with bumping into enemy if can use shockwave

	Mesh = SkeletalMesh'PoltergeistMesh'
	RedSkin  = Shader'EnergyTankShaderRed'
	BlueSkin = Shader'EnergyTankShaderBlue'
	RanOverDamageType = class'DamTypePoltergeistRoadkill'
	CrushedDamageType = class'DamTypePoltergeistPancake'

	FPCamPos=(X=-25,Y=-32,Z=200)
	FPCamViewOffset=(X=90,Y=0,Z=0)
	//bFPNoZFromCameraPitch=True
	TPCamLookat=(X=-50,Y=0,Z=0)
	TPCamWorldOffset=(X=0,Y=0,Z=300)
	TPCamDistance=375

	MaxGroundSpeed = 800.0

	VehiclePositionString = "in a Poltergeist"
	VehicleNameString     = "Poltergeist"
	VehicleDescription    = "Poltergeists are appearant manifestations of invisible, but noisy, disruptive or destructive entities. This hover tank certainly is a destructive entity when it uses its heat ray and energy shock wave."
	VehicleIcon           = (Material=Texture'PoltergeistIcon',X=1,Y=1,SizeX=126,SizeY=62,bIsGreyScale=true) // makes UTPlus happier
	bShowChargingBar      = True

	DisintegrationEffectClass = class'PoltergeistExplosionEffect'
}