WVPersesMAS.PersesMAS

/******************************************************************************
PersesMAS

Creation date: 2011-08-18 21:35
Last change: $Id$
Copyright © 2011, Wormbo
Website: http://www.koehler-homepage.de/Wormbo/
Feel free to reuse this code. Send me a note if you found it helpful or want
to report bugs/provide improvements.
Please ask for permission first, if you intend to make money off reused code.
******************************************************************************/

class PersesMAS extends ONSWheeledCraft;


#exec obj load file=PersesMesh.ukx package=WVPersesMAS


var() const editconst string Build;

var array<vector> GunnerTurretAttachOffsets;
var vector GunMountOffset;
var float GunMountScale;
var array<name> HiddenBones;
var array<Material> DestroyedSkins;
var float ThrottleFixTime, FixedThrottle, FixedSteering, BotEnterTime;


simulated function String GetDebugName()
{
	return Name$" (build "$Build$")";
}

simulated function PostNetBeginPlay()
{
	local int i;

	for (i = 0; i < HiddenBones.Length; ++i) {
		SetBoneScale(i, 0.0, HiddenBones[i]);
	}

	SetBoneLocation('LeftFrontGunMount',  GunMountOffset);
	SetBoneLocation('RightFrontGunMount', GunMountOffset * vect(1,-1,1));
	SetBoneLocation('LeftRearGunMount',   GunMountOffset * vect(-1,1,1));
	SetBoneLocation('RightRearGunMount',  GunMountOffset * vect(-1,-1,1));
	SetBoneScale(i++, GunMountScale, 'LeftFrontGunMount');
	SetBoneScale(i++, GunMountScale, 'RightFrontGunMount');
	SetBoneScale(i++, GunMountScale, 'LeftRearGunMount');
	SetBoneScale(i++, GunMountScale, 'RightRearGunMount');

	SetBoneScale(i++, 0.001, 'RocketArm');
	SetBoneScale(i++, 1100.0, 'RocketPost');

	for (i = 0; i < PassengerWeapons.Length; i++) {
		SetBoneLocation(PassengerWeapons[i].WeaponBone, GunnerTurretAttachOffsets[i]);
	}


	//AnimBlendParams(1, 1.0, 0.0, 0.0, 'MainGunPowerBase');
	//AnimBlendParams(1, 1.0, 0.0, 0.0, 'MainGunPost');
	//PlayAnim('MASMainGunHide',,, 1);
	//FreezeAnimAt(0.0, 1);
	//PlayAnim('MASMainGunDeploy',,, 2);
	//FreezeAnimAt(0.0, 2);

	Super.PostNetBeginPlay();

	//if (WeaponPawns.Length > 1 && WeaponPawns[1] != None && PersesTankTurret(WeaponPawns[1].Gun) != None)
	//	PersesTankTurret(WeaponPawns[1].Gun).SetLeftTurret(); // invert aim yaw constraints
}


function bool ImportantVehicle()
{
	return true;
}

function bool NeedToTurn(vector targ)
{
	// rocket pack turns quickly enough to allow approximately spamming in the desired direction
	return (ActiveWeapon >= Weapons.Length || Weapons[ActiveWeapon].bCorrectAim
		|| vector(Weapons[ActiveWeapon].CurrentAim) dot Normal(targ - Weapons[ActiveWeapon].Location) > 0.9);
}

/** Pick most efficient projectile type for the target to attack. */
function ChooseFireAt(Actor A)
{
	local byte BestType;
	local float Dist;
	local Pawn P;
	local int AdditionalTargets;
	
	if (A != None)
	{
		if (ActiveWeapon < Weapons.Length && !Weapons[ActiveWeapon].bCorrectAim)
			BestType = 1; // homing missiles, because not aiming correctly yet
		else
			BestType = 0; // mercury missile
		Dist = VSize(Location - A.Location);
		if (Dist > 3000 && Dist < 15000 && (Pawn(A) == None || Pawn(A).GroundSpeed < 500))
		{
			foreach RadiusActors(class'Pawn', P, 2000, A.Location)
			{
				if (P.Health > 0 && P.bCollideActors && (P.GetTeamNum() == 255 || P.GetTeamNum() != Instigator.GetTeamNum()) && (Vehicle(P) == None || Vehicle(P).IndependentVehicle()))
				{
					AdditionalTargets++;
				}
			}
		}
		if (AdditionalTargets > 1)
		{
			BestType = 2; // frag missiles
		}
		if (AdditionalTargets < 4)
		{
			if (Pawn(A) != None && Pawn(A).bCanFly || ONSVehicle(A) != None && ONSVehicle(A).FastVehicle())
			{
				BestType = 1; // homing missiles
			}
			else if (DestroyableObjective(A) != None || DestroyableObjective(A.Owner) != None || Pawn(A) != None && (Pawn(A).GroundSpeed < 700 && A.CollisionRadius > 200 || Pawn(A).bStationary))
			{
				BestType = 3; // napalm rockets
			}
		}
	}
	else
		log(Self@"firing without target"@A);
	
	if (ActiveWeapon < Weapons.Length && PersesRocketPack(Weapons[ActiveWeapon]) != None)
		PersesRocketPack(Weapons[ActiveWeapon]).ChangeProjectile(BestType);
	
	Super.ChooseFireAt(A);
}

function float BotDesireability(Actor S, int TeamIndex, Actor Objective)
{
	local SquadAI Squad;

	Squad = SquadAI(S);

	if (Squad.GetOrders() == 'Defend')
		return 0;

	return super.BotDesireability(S,TeamIndex, Objective);
}

function AltFire(optional float F)
{
	local PlayerController PC;

	PC = PlayerController(Controller);
	if (PC == None)
		return;

	bWeaponIsAltFiring = true;
	PC.ToggleZoom();
}

function ClientVehicleCeaseFire(bool bWasAltFire)
{
	local PlayerController PC;

	if (!bWasAltFire)
	{
		Super.ClientVehicleCeaseFire(bWasAltFire);
		return;
	}

	PC = PlayerController(Controller);
	if (PC == None)
		return;

	bWeaponIsAltFiring = false;
	PC.StopZoom();
}

simulated function ClientKDriverLeave(PlayerController PC)
{
	Super.ClientKDriverLeave(PC);

	bWeaponIsAltFiring = false;
	PC.EndZoom();
}

function Vehicle FindEntryVehicle(Pawn P)
{
	local Bot B;
	local int i;
	local Vehicle EntryVehicle;

	B = Bot(P.Controller);
	if (B == None || WeaponPawns.Length == 0 || !IsVehicleEmpty() && Driver == None)
	{
		EntryVehicle = Super.FindEntryVehicle(P);
	}
	else
	{
		i = Rand(WeaponPawns.Length);
		if (WeaponPawns[i].Driver == None)
			EntryVehicle =  WeaponPawns[i];
		else
			EntryVehicle =  Super.FindEntryVehicle(P);
	}
	if (EntryVehicle == None && Driver != None)
	{
		// If a player is trying to drive and we're full of bots, kick out the bot driver so the player can drive
		if (PlayerController(P.Controller) != None && Bot(Controller) != None && Controller.SameTeamAs(P.Controller)) {
			KDriverLeave(true);
			return self;
		}
	}
	else return EntryVehicle;
}

function KDriverEnter(Pawn P)
{
	Super.KDriverEnter(P);

	BotEnterTime = Level.TimeSeconds;
}

simulated event DestroyAppearance()
{
	local int i;

	// For replication
	bDestroyAppearance = True;

	// Put brakes on
	Throttle	= 0;
	Steering	= 0;
	Rise		= 0;

	// Destroy the weapons
	if (Role == ROLE_Authority) {
		for (i = 0; i < Weapons.Length; i++) {
			if (Weapons[i] != None)
				Weapons[i].Destroy();
		}
		for(i = 0; i < WeaponPawns.Length; i++)
			WeaponPawns[i].Destroy();
	}
	Weapons.Length = 0;
	WeaponPawns.Length = 0;

	// Destroy the effects
	if (Level.NetMode != NM_DedicatedServer) {
		bNoTeamBeacon = true;

		for (i = 0; i < HeadlightCorona.Length; i++)
			HeadlightCorona[i].Destroy();
		HeadlightCorona.Length = 0;

		if (HeadlightProjector != None)
			HeadlightProjector.Destroy();
	}

	// Become the dead vehicle mesh
	Skins = DestroyedSkins;
	RepSkin = Skins[0];
	NetPriority = 2;
}


simulated event ClientVehicleExplosion(bool bFinal)
{
	local int SoundNum;
	local Actor DestructionEffect;

	// Explosion effect
	if (ExplosionSounds.Length > 0) {
		SoundNum = Rand(ExplosionSounds.Length);
		PlaySound(ExplosionSounds[SoundNum], SLOT_None, ExplosionSoundVolume*TransientSoundVolume,, ExplosionSoundRadius);
	}

	if (bFinal) {
		if (Level.NetMode != NM_DedicatedServer)
			DestructionEffect = Spawn(DisintegrationEffectClass,,, Location, Rotation);

		GotoState('VehicleDisintegrated');
	}
}

state VehicleDisintegrated
{
	ignores Died;

Begin:
	Sleep(0.75);
	Destroy();
}

function ServerChangeDriverPosition(byte F)
{
	if ((F == 0 || F > WeaponPawns.Length + 1) && ActiveWeapon < Weapons.Length && PersesRocketPack(Weapons[ActiveWeapon]) != None)
		PersesRocketPack(Weapons[ActiveWeapon]).ChangeProjectile(F - WeaponPawns.Length - 2);
	else
		Super.ServerChangeDriverPosition(F);
}

simulated function Tick(float DeltaTime)
{
	Super.Tick(DeltaTime);
	
	if (Bot(Controller) != None)
	{
		if (Level.TimeSeconds - BotEnterTime < 1.0)
		{
			// wait for potential passengers
			Throttle = 0.0;
			Steering = 0.0;
		}
		else if (VSize(Velocity) < 10 && EngineRPM > 700 || Level.TimeSeconds - ThrottleFixTime < 1.5)
		{
			// bot got stuck somewhere and doesn't notice
			if (Level.TimeSeconds - ThrottleFixTime > 1.5)
			{
				ThrottleFixTime = Level.TimeSeconds;
				if (Gear == 0)
					FixedThrottle = 1.0; // stuck in reverse, try forward instead
				else
					FixedThrottle = -1.0; // stuck in forward, try reverse instead
				FixedSteering = -Steering * Rand(2); // randomly back up straight (in case bot managed to get stuck in narrow passage)
			}
			//if (Level.TimeSeconds - ThrottleFixTime < 1.0)
			//	Steering = 0.0; // bots usually get stuck trying to turn, so backing up straight shouldn't break anything
			Throttle = FixedThrottle;
			Steering = FixedSteering;
		}
		// TODO: slow down to allow additional passengers to catch up
	}
}

simulated function DrawHud(Canvas C)
{
	local Hud H;
	
	Super.DrawHud(C);
	
	H = C.Viewport.Actor.MyHud;
	if (H == None || H.bShowDebugInfo || H.bHideHud || H.bShowLocalStats || H.bShowScoreBoard || H.PlayerOwner == None || H.PawnOwner == None || H.PawnOwnerPRI == None || H.PlayerOwner.IsSpectating() && H.PlayerOwner.bBehindView)
		return; // don't draw weapon bar on spectator HUD
	
	if (ActiveWeapon < Weapons.Length && PersesRocketPack(Weapons[ActiveWeapon]) != None)
		PersesRocketPack(Weapons[ActiveWeapon]).DrawWeaponBar(C);
}


//=============================================================================
// Default values
//=============================================================================

defaultproperties
{
	Build = "%%%%-%%-%% %%:%%"
	VehiclePositionString="in a Perses"
	VehicleNameString="Perses MAS"
	VehicleDescription="Perses, the ancient Greek Titan god of destruction. And destruction is what the Perses Mobile Assault Station is all about."

	Mesh=Mesh'PersesChassis'

	HiddenBones = ("LeftFrontArm1","RightFrontArm1","LeftRearArm1","RightRearArm1")

	DriverWeapons(0) = (WeaponClass=class'PersesRocketPack',WeaponBone=RocketPackAttach)
	bHasAltFire = False
	bSeparateTurretFocus = True

	PassengerWeapons(0)=(WeaponPawnClass=class'PersesTankTurretPawn',WeaponBone=RightFrontGunAttach)
	PassengerWeapons(1)=(WeaponPawnClass=class'PersesTankTurretPawn',WeaponBone=LeftFrontGunAttach)
	PassengerWeapons(2)=(WeaponPawnClass=class'PersesArtilleryTurretPawn',WeaponBone=RightRearGunAttach)
	PassengerWeapons(3)=(WeaponPawnClass=class'PersesArtilleryTurretPawn',WeaponBone=LeftRearGunAttach)

	GunMountOffset=(X=32,Z=3)
	GunMountScale=1.4
	GunnerTurretAttachOffsets(0)=(Z=2.5)
	GunnerTurretAttachOffsets(1)=(Z=2.5)
	GunnerTurretAttachOffsets(2)=(X=-2,Z=3)
	GunnerTurretAttachOffsets(3)=(X=-2,Z=3)

	DestroyedSkins = (Texture'ONSFullTextures.DeadTextures.MASdeadTEX')
	DestructionEffectClass=class'Onslaught.ONSVehicleExplosionEffect'
	DisintegrationEffectClass=class'PersesDeathExplosion'
	DestructionLinearMomentum=(Min=250000,Max=400000)
	DestructionAngularMomentum=(Min=100,Max=300)

	RedSkin=Shader'ONSFullTextures.MASGroup.MASRedShad'
	BlueSkin=Shader'ONSFullTextures.MASGroup.MASBlueShad'
	ShadowCullDistance=2000.0

	Health=7000
	HealthMax=7000
	DisintegrationHealth=0
	DriverDamageMult=0.0
	MomentumMult=0.01
	UpsideDownDamage=500.0
	RanOverDamageType=class'DamTypePersesRoadkill'
	CrushedDamageType=class'DamTypePersesPancake'

	ExplosionDamage=250.0
	ExplosionRadius=500.0

	AirPitchDamping=45.0

	FPCamPos=(X=-350,Y=0,Z=350)
	TPCamLookat=(X=-350,Y=0,Z=300)
	TPCamWorldOffset=(X=0,Y=0,Z=200)
	TPCamDistance=780
	TPCamDistRange=(Min=0,Max=2500)

	bDrawDriverInTP=False
	bDrawMeshInFP=True
	bAllowBigWheels=True

	CollisionHeight=+60.0
	CollisionRadius=+260.0
	NavigationPointRange=+190.0
	bSuperSize=true

	DrivePos=(X=16.921,Y=-40.284,Z=65.794)
	DriveRot=(Pitch=0)

	IdleSound=sound'ONSVehicleSounds-S.MAS.MASEng01'
	StartUpSound=sound'ONSVehicleSounds-S.MAS.MASStart01'
	ShutDownSound=sound'ONSVehicleSounds-S.MAS.MASStop01'
	EngineRPMSoundRange=8000
	SoundRadius=255
	SoundVolume=255
	IdleRPM=1000
	RevMeterScale=4000

	StartUpForce="MASStartUp"
	ShutDownForce="MASShutDown"

	SteerBoneName=""
	SteerBoneAxis=AXIS_Z
	SteerBoneMaxAngle=90

	EntryPosition=(X=0,Y=0,Z=0)
	EntryRadius=500.0

	ExitPositions(0)=(X=0,Y=-365,Z=200)
	ExitPositions(1)=(X=0,Y=365,Z=200)
	ExitPositions(2)=(X=0,Y=-365,Z=-100)
	ExitPositions(3)=(X=0,Y=365,Z=-100)

	WheelPenScale=1.0
	WheelPenOffset=0.01
	WheelSoftness=0.04
	WheelRestitution=0.1
	WheelAdhesion=0.0
	WheelLongFrictionFunc=(Points=((InVal=0,OutVal=0.0),(InVal=50.0,OutVal=1.0),(InVal=100.0,OutVal=0.9),(InVal=10000000000.0,OutVal=0.9)))
	WheelLongFrictionScale=0.9
	WheelLatFrictionScale=1.5
	WheelLongSlip=0.001
	WheelLatSlipFunc=(Points=((InVal=0.0,OutVal=0.0),(InVal=30.0,OutVal=0.009),(InVal=45.0,OutVal=0.00),(InVal=10000000000.0,OutVal=0.00)))
	WheelHandbrakeSlip=0.01
	WheelHandbrakeFriction=0.1
	WheelSuspensionTravel=40.0
	WheelSuspensionOffset=0.0
	WheelSuspensionMaxRenderTravel=40.0

	HandbrakeThresh=200
	FTScale=0.01
	ChassisTorqueScale=0.1

	MinBrakeFriction=4.0
	MaxBrakeTorque=20.0
	MaxSteerAngleCurve=(Points=((InVal=0,OutVal=40.0),(InVal=700.0,OutVal=20.0),(InVal=1000000000.0,OutVal=10.0)))
	SteerSpeed=110
	StopThreshold=100
	TorqueCurve=(Points=((InVal=0,OutVal=36.0),(InVal=200,OutVal=5.0),(InVal=1500,OutVal=6.0),(InVal=2500,OutVal=0.0)))
	EngineBrakeFactor=0.002
	EngineBrakeRPMScale=0.1
	EngineInertia=0.5
	WheelInertia=0.01

	TransRatio=0.11
//	TransRatio=0.01
	GearRatios[0]=-0.2
	GearRatios[1]=0.2
	NumForwardGears=1
	ChangeUpPoint=2000
	ChangeDownPoint=1000
	LSDFactor=1.0

//	VehicleMass=25.0
	VehicleMass=12.0

	HeadlightCoronaOffset(0)=(X=365,Y=-87,Z=130)
	HeadlightCoronaMaterial=Material'EpicParticles.flashflare1'
	HeadlightCoronaMaxSize=120

	DamagedEffectOffset=(X=300,Y=0,Z=185)
	DamagedEffectScale=2.5

	Begin Object Class=KarmaParamsRBFull Name=KParams0
		KStartEnabled=True
		KFriction=0.5
		KLinearDamping=0.05
		KAngularDamping=0.05
		KImpactThreshold=500
		bKNonSphericalInertia=True
		bHighDetailOnly=False
		bClientOnly=False
		bKDoubleTickRate=True
		KInertiaTensor(0)=1.260000
		KInertiaTensor(1)=0
		KInertiaTensor(2)=0
		KInertiaTensor(3)=3.099998
		KInertiaTensor(4)=0
		KInertiaTensor(5)=4.499996

		KMaxSpeed=650.0

		KCOMOffset=(X=0,Y=0,Z=0)
		bDestroyOnWorldPenetrate=True
		bDoSafetime=True
	End Object
	KParams=KarmaParams'KParams0'

	Begin Object Class=SVehicleWheel Name=RightRearTIRE
		BoneName="RightRearTire"
		BoneRollAxis=AXIS_Y
		BoneSteerAxis=AXIS_Z
		BoneOffset=(X=0.0,Y=0.0,Z=0.0)
		WheelRadius=99
		bPoweredWheel=True
		SteerType=VST_Fixed
//		SupportBoneName="RightRearStrut"
	End Object
	Wheels(0)=SVehicleWheel'RightRearTIRE'

	Begin Object Class=SVehicleWheel Name=LeftRearTIRE
		BoneName="LeftRearTire"
		BoneRollAxis=AXIS_Y
		BoneSteerAxis=AXIS_Z
		BoneOffset=(X=0.0,Y=0.0,Z=0.0)
		WheelRadius=99
		bPoweredWheel=True
		SteerType=VST_Fixed
//		SupportBoneName="LeftRearStrut"
	End Object
	Wheels(1)=SVehicleWheel'LeftRearTIRE'

	Begin Object Class=SVehicleWheel Name=RightFrontTIRE
		BoneName="RightFrontTire"
		BoneRollAxis=AXIS_Y
		BoneSteerAxis=AXIS_Z
		BoneOffset=(X=0.0,Y=0.0,Z=0.0)
		WheelRadius=99
		bPoweredWheel=True
		SteerType=VST_Steered
//		SupportBoneName="RightFrontStrut"
	End Object
	Wheels(2)=SVehicleWheel'RightFrontTIRE'

	Begin Object Class=SVehicleWheel Name=LeftFrontTIRE
		BoneName="LeftFrontTire"
		BoneRollAxis=AXIS_Y
		BoneSteerAxis=AXIS_Z
		BoneOffset=(X=0.0,Y=0.0,Z=0.0)
		WheelRadius=99
		bPoweredWheel=True
		SteerType=VST_Steered
//		SupportBoneName="LeftFrontStrut"
	End Object
	Wheels(3)=SVehicleWheel'LeftFrontTIRE'

	bDriverHoldsFlag=false
	FlagBone=LeftFrontGunAttach
	bKeyVehicle=true
	bNeverReset=true

	bEnableProximityViewShake=true
	bOnlyViewShakeIfDriven=true
	ViewShakeRadius=1000.0
	ViewShakeOffsetMag=(X=0.7,Y=0.0,Z=2.7)
	ViewShakeOffsetFreq=7.0

	HornSounds(0)=sound'ONSVehicleSounds-S.LevHorn01'
	HornSounds(1)=sound'ONSVehicleSounds-S.LevHorn02'

	MaxDesireability=2.0
	ObjectiveGetOutDist=3000.0
}